pkgs/applications/video/kodi/wrapper.nix

   1 { lib, makeWrapper, buildEnv, kodi, addons, callPackage }:
   2
   3 let
   4   kodiPackages = callPackage ../../../top-level/kodi-packages.nix { inherit kodi; };
   5
   6   # linux distros are supposed to provide pillow and pycryptodome
   7   requiredPythonPath = with kodi.pythonPackages; makePythonPath ([ pillow pycryptodome ]);
   8
   9   # each kodi addon can potentially export a python module which should be included in PYTHONPATH
  10   # see any addon which supplies `passthru.pythonPath` and the corresponding entry in the addons `addon.xml`
  11   # eg. `<extension point="xbmc.python.module" library="lib" />` -> pythonPath = "lib";
  12   additionalPythonPath =
  13     let
  14       addonsWithPythonPath = lib.filter (addon: addon ? pythonPath) addons;
  15     in
  16       lib.concatMapStringsSep ":" (addon: "${addon}${kodiPackages.addonDir}/${addon.namespace}/${addon.pythonPath}") addonsWithPythonPath;
  17 in
  18
  19 buildEnv {
  20   name = "${kodi.name}-env";
  21
  22   paths = [ kodi ] ++ addons;
  23   pathsToLink = [ "/share" ];
  24
  25   nativeBuildInputs = [ makeWrapper ];
  26
  27   postBuild = ''
  28     mkdir $out/bin
  29     for exe in kodi{,-standalone}
  30     do
  31       makeWrapper ${kodi}/bin/$exe $out/bin/$exe \
  32         --prefix PYTHONPATH : ${requiredPythonPath}:${additionalPythonPath} \
  33         --prefix KODI_HOME : $out/share/kodi \
  34         --prefix LD_LIBRARY_PATH ":" "${lib.makeLibraryPath
  35           (lib.concatMap
  36             (plugin: plugin.extraRuntimeDependencies or []) addons)}"
  37     done
  38   '';
  39 }