pkgs/applications/video/losslesscut-bin/build-from-appimage.nix

   1 { appimageTools
   2 , fetchurl
   3 , makeWrapper
   4 , pname
   5 , version
   6 , hash
   7 , metaCommon ? { }
   8 }:
   9
  10 let
  11   pname = "losslesscut";
  12
  13   src = fetchurl {
  14     url = "https://github.com/mifi/lossless-cut/releases/download/v${version}/LosslessCut-linux-x86_64.AppImage";
  15     inherit hash;
  16   };
  17
  18   extracted = appimageTools.extractType2 {
  19     inherit pname version src;
  20   };
  21 in
  22 appimageTools.wrapType2 {
  23   inherit pname version src;
  24
  25   nativeBuildInputs = [ makeWrapper ];
  26
  27   profile = ''
  28     export LC_ALL=C.UTF-8
  29   '';
  30
  31   extraInstallCommands = ''
  32     (
  33       mkdir -p $out/share
  34       cd ${extracted}/usr
  35       find share -mindepth 1 -type d -exec mkdir -p $out/{} \;
  36       find share -mindepth 1 -type f,l -exec ln -s $PWD/{} $out/{} \;
  37     )
  38     ln -s ${extracted}/losslesscut.png $out/share/icons/losslesscut.png
  39     mkdir $out/share/applications
  40     cp ${extracted}/losslesscut.desktop $out/share/applications
  41     substituteInPlace $out/share/applications/losslesscut.desktop \
  42       --replace AppRun losslesscut
  43     wrapProgram "$out/bin/losslesscut" \
  44       --add-flags "--disable-seccomp-filter-sandbox"
  45   '';
  46
  47   meta = metaCommon // {
  48     platforms = [ "x86_64-linux" ];
  49     mainProgram = "losslesscut";
  50   };
  51 }