pkgs/applications/video/obs-studio/plugins/obs-vkcapture.nix

   1 { lib
   2 , stdenv
   3 , fetchFromGitHub
   4 , cmake
   5 , pkg-config
   6 , ninja
   7 , wayland
   8 , wayland-scanner
   9 , obs-studio
  10 , libffi
  11 , libX11
  12 , libXau
  13 , libXdmcp
  14 , libxcb
  15 , vulkan-headers
  16 , vulkan-loader
  17 , libGL
  18 , obs-vkcapture32
  19 }:
  20
  21 stdenv.mkDerivation (finalAttrs: {
  22   pname = "obs-vkcapture";
  23   version = "1.5.1";
  24
  25   src = fetchFromGitHub {
  26     owner = "nowrep";
  27     repo = "obs-vkcapture";
  28     rev = "v${finalAttrs.version}";
  29     hash = "sha256-RIDsT6eL6bUfqPiyPlecnZHu5OorcJb3Xal8pjdOpAA=";
  30   };
  31
  32   cmakeFlags = lib.optionals stdenv.hostPlatform.isi686 [
  33     # We don't want to build the plugin for 32bit. The library integrates with
  34     # the 64bit plugin but it's necessary to be loaded into 32bit games.
  35     "-DBUILD_PLUGIN=OFF"
  36   ];
  37
  38   nativeBuildInputs = [ cmake ninja pkg-config wayland-scanner ];
  39   buildInputs = [
  40     libGL
  41     libffi
  42     libX11
  43     libXau
  44     libXdmcp
  45     libxcb
  46     vulkan-headers
  47     vulkan-loader
  48     wayland
  49   ]
  50   ++ lib.optionals (!stdenv.hostPlatform.isi686) [
  51     obs-studio
  52   ];
  53
  54   postPatch = ''
  55     substituteInPlace src/glinject.c \
  56       --replace "libGLX.so.0" "${lib.getLib libGL}/lib/libGLX.so.0" \
  57       --replace "libX11.so.6" "${lib.getLib libX11}/lib/libX11.so.6" \
  58       --replace "libX11-xcb.so.1" "${lib.getLib libX11}/lib/libX11-xcb.so.1" \
  59       --replace "libxcb-dri3.so.0" "${lib.getLib libxcb}/lib/libxcb-dri3.so.0" \
  60       --replace "libEGL.so.1" "${lib.getLib libGL}/lib/libEGL.so.1" \
  61       --replace "libvulkan.so.1" "${lib.getLib vulkan-loader}/lib/libvulkan.so.1"
  62   '';
  63
  64   # Support 32bit Vulkan applications by linking in the 32bit Vulkan layer and
  65   # the wrapper executables. Note that vkcapture and glcapture are themselves
  66   # wrapper scripts that simply exec gamecapture and print a warning but because
  67   # they take gamecapture from PATH, we must link them to the 32 bit gamecapture
  68   # directly.
  69   postInstall = lib.optionalString (stdenv.hostPlatform.system == "x86_64-linux") ''
  70     ln -s ${obs-vkcapture32}/share/vulkan/implicit_layer.d/obs_vkcapture_32.json \
  71       "$out/share/vulkan/implicit_layer.d/"
  72     for bin in ${obs-vkcapture32}/bin/* ; do
  73       ln -s ${obs-vkcapture32}/bin/obs-gamecapture "$out/bin/$(basename "$bin")32"
  74     done
  75   '';
  76
  77   meta = with lib; {
  78     description = "OBS Linux Vulkan/OpenGL game capture";
  79     homepage = "https://github.com/nowrep/obs-vkcapture";
  80     changelog = "https://github.com/nowrep/obs-vkcapture/releases/tag/v${finalAttrs.version}";
  81     maintainers = with maintainers; [ atila pedrohlc ];
  82     license = licenses.gpl2Only;
  83     platforms = platforms.linux;
  84   };
  85 })