pkgs/applications/window-managers/hyprwm/hypr/default.nix

   1 { lib
   2 , stdenv
   3 , fetchFromGitHub
   4 , cairo
   5 , cmake
   6 , glib
   7 , gtkmm3
   8 , harfbuzz
   9 , libX11
  10 , libXdmcp
  11 , libxcb
  12 , makeWrapper
  13 , pcre2
  14 , pkg-config
  15 , xcbutilcursor
  16 , xcbutilkeysyms
  17 , xcbutilwm
  18 , xcbutil
  19 , xmodmap
  20 }:
  21
  22 stdenv.mkDerivation (finalAttrs: {
  23   pname = "hypr";
  24   version = "unstable-2023-01-26";
  25
  26   src = fetchFromGitHub {
  27     owner = "hyprwm";
  28     repo = "Hypr";
  29     rev = "af4641847b578b233a6f06806f575b3f320d74da";
  30     hash = "sha256-FUKR5nceEhm9GWa61hHO8+y4GBz7LYKXPB0OpQcQ674=";
  31   };
  32
  33   patches = [
  34     ./000-dont-set-compiler.diff
  35   ];
  36
  37   nativeBuildInputs = [
  38     cmake
  39     makeWrapper
  40     pkg-config
  41   ];
  42
  43   buildInputs = [
  44     cairo
  45     glib
  46     gtkmm3
  47     harfbuzz
  48     libX11
  49     libXdmcp
  50     libxcb
  51     pcre2
  52     xcbutilcursor
  53     xcbutilkeysyms
  54     xcbutilwm
  55     xcbutil
  56   ];
  57
  58   # src/ewmh/ewmh.cpp:67:28: error: non-constant-expression cannot be narrowed from type 'int' to 'uint32_t' (aka 'unsigned int') in initializer list
  59   env.NIX_CFLAGS_COMPILE = lib.optionalString stdenv.hostPlatform.isDarwin "-Wno-c++11-narrowing";
  60
  61   installPhase = ''
  62     runHook preInstall
  63
  64     install -Dm755 Hypr -t $out/bin
  65
  66     runHook postInstall
  67   '';
  68
  69   postFixup = ''
  70     wrapProgram $out/bin/Hypr --prefix PATH : ${lib.makeBinPath [ xmodmap ]}
  71   '';
  72
  73   meta = with lib; {
  74     inherit (finalAttrs.src.meta) homepage;
  75     description = "Tiling X11 window manager written in modern C++";
  76     license = licenses.bsd3;
  77     maintainers = with maintainers; [ AndersonTorres ];
  78     inherit (libX11.meta) platforms;
  79     mainProgram = "Hypr";
  80   };
  81 })