pkgs/by-name/ka/katawa-shoujo-re-engineered/package.nix

   1 {
   2   lib,
   3   stdenvNoCC,
   4   fetchFromGitea,
   5   makeDesktopItem,
   6   copyDesktopItems,
   7   makeWrapper,
   8   renpy,
   9   nix-update-script,
  10 }:
  11 stdenvNoCC.mkDerivation (finalAttrs: {
  12   pname = "katawa-shoujo-re-engineered";
  13   version = "1.4.8";
  14
  15   src = fetchFromGitea {
  16     # GitHub mirror at fleetingheart/ksre
  17     domain = "codeberg.org";
  18     owner = "fhs";
  19     repo = "katawa-shoujo-re-engineered";
  20     rev = "v${finalAttrs.version}";
  21     hash = "sha256-y128bnRZtW5DgiP43OAnkhhq3f5F88jUl1Bku6wef+w=";
  22   };
  23
  24   desktopItems = [
  25     (makeDesktopItem {
  26       name = "katawa-shoujo-re-engineered";
  27       desktopName = "Katawa Shoujo: Re-Engineered";
  28       type = "Application";
  29       icon = finalAttrs.meta.mainProgram;
  30       categories = [ "Game" ];
  31       exec = finalAttrs.meta.mainProgram;
  32     })
  33   ];
  34
  35   nativeBuildInputs = [
  36     makeWrapper
  37     copyDesktopItems
  38   ];
  39
  40   dontBuild = true;
  41
  42   installPhase = ''
  43     runHook preInstall
  44
  45     mkdir -p $out/bin
  46     makeWrapper ${lib.getExe' renpy "renpy"} $out/bin/${finalAttrs.meta.mainProgram} \
  47       --add-flags ${finalAttrs.src} --add-flags run
  48     install -D $src/web-icon.png $out/share/icons/hicolor/512x512/apps/${finalAttrs.meta.mainProgram}.png
  49
  50     runHook postInstall
  51   '';
  52
  53   passthru.updateScript = nix-update-script { };
  54
  55   meta = {
  56     description = "Fan-made modernization of the classic visual novel Katawa Shoujo";
  57     homepage = "https://www.fhs.sh/projects";
  58     license = with lib.licenses; [
  59       # code
  60       mpl20
  61       # assets from the original game
  62       cc-by-nc-nd-30
  63     ];
  64     mainProgram = "katawa-shoujo-re-engineered";
  65     maintainers = with lib.maintainers; [ quantenzitrone rapiteanu ];
  66     platforms = renpy.meta.platforms;
  67   };
  68 })