pkgs/desktops/lxqt/lxqt-qtplugin/default.nix

   1 { lib
   2 , stdenv
   3 , fetchFromGitHub
   4 , cmake
   5 , libdbusmenu-lxqt
   6 , libdbusmenu ? null
   7 , libfm-qt
   8 , libqtxdg
   9 , lxqt-build-tools
  10 , gitUpdater
  11 , qtbase
  12 , qtsvg
  13 , qttools
  14 , wrapQtAppsHook
  15 , version ? "2.0.0"
  16 }:
  17
  18 stdenv.mkDerivation rec {
  19   pname = "lxqt-qtplugin";
  20   inherit version;
  21
  22   src = fetchFromGitHub {
  23     owner = "lxqt";
  24     repo = pname;
  25     rev = version;
  26     hash = {
  27       "1.4.1" = "sha256-sp/LvQNfodMYQ4kNbBv4PTNfs38XjYLezuxRltZd4kc=";
  28       "2.0.0" = "sha256-o5iD4VzsbN81lwDZJuFj8Ugg1RP752M4unu3J5/h8g8=";
  29     }."${version}";
  30   };
  31
  32   nativeBuildInputs = [
  33     cmake
  34     lxqt-build-tools
  35     qttools
  36     wrapQtAppsHook
  37   ];
  38
  39   buildInputs = [
  40     (if lib.versionAtLeast version "2.0.0" then libdbusmenu-lxqt else libdbusmenu)
  41     libfm-qt
  42     libqtxdg
  43     qtbase
  44     qtsvg
  45   ];
  46
  47   postPatch = ''
  48     substituteInPlace src/CMakeLists.txt \
  49       --replace-fail "DESTINATION \"\''${QT_PLUGINS_DIR}" "DESTINATION \"$qtPluginPrefix"
  50   '';
  51
  52   passthru.updateScript = gitUpdater { };
  53
  54   meta = with lib; {
  55     homepage = "https://github.com/lxqt/lxqt-qtplugin";
  56     description = "LXQt Qt platform integration plugin";
  57     license = licenses.lgpl21Plus;
  58     platforms = platforms.linux;
  59     maintainers = teams.lxqt.members;
  60   };
  61 }