pkgs/desktops/mate/mate-session-manager/default.nix

   1 { lib
   2 , stdenv
   3 , fetchurl
   4 , pkg-config
   5 , gettext
   6 , xtrans
   7 , dbus-glib
   8 , systemd
   9 , libSM
  10 , libXtst
  11 , glib
  12 , gtk3
  13 , libepoxy
  14 , polkit
  15 , hicolor-icon-theme
  16 , mate-desktop
  17 , mate-screensaver
  18 , wrapGAppsHook3
  19 , fetchpatch
  20 , mateUpdateScript
  21 }:
  22
  23 stdenv.mkDerivation rec {
  24   pname = "mate-session-manager";
  25   version = "1.28.0";
  26
  27   src = fetchurl {
  28     url = "https://pub.mate-desktop.org/releases/${lib.versions.majorMinor version}/${pname}-${version}.tar.xz";
  29     sha256 = "0yzkWVuh2mUpB3cgPyvIK9lzshSjoECAoe9caJkKLXs=";
  30   };
  31
  32   patches = [
  33     # allow turning on debugging from environment variable
  34     (fetchpatch {
  35       url = "https://github.com/mate-desktop/mate-session-manager/commit/3ab6fbfc811d00100d7a2959f8bbb157b536690d.patch";
  36       sha256 = "0yjaklq0mp44clymyhy240kxlw95z3azmravh4f5pfm9dys33sg0";
  37     })
  38   ];
  39
  40   nativeBuildInputs = [
  41     pkg-config
  42     gettext
  43     xtrans
  44     wrapGAppsHook3
  45   ];
  46
  47   buildInputs = [
  48     dbus-glib
  49     systemd
  50     libSM
  51     libXtst
  52     gtk3
  53     mate-desktop
  54     mate-screensaver # for gsm_manager_init
  55     hicolor-icon-theme
  56     libepoxy
  57     polkit
  58   ];
  59
  60   enableParallelBuilding = true;
  61
  62   env.NIX_CFLAGS_COMPILE = "-I${glib.dev}/include/gio-unix-2.0";
  63
  64   postFixup = ''
  65     substituteInPlace $out/share/xsessions/mate.desktop \
  66       --replace-fail "Exec=mate-session" "Exec=$out/bin/mate-session"
  67   '';
  68
  69   passthru.providedSessions = [ "mate" ];
  70
  71   passthru.updateScript = mateUpdateScript { inherit pname; };
  72
  73   meta = with lib; {
  74     description = "MATE Desktop session manager";
  75     homepage = "https://github.com/mate-desktop/mate-session-manager";
  76     license = with licenses; [ gpl2Plus lgpl2Plus ];
  77     platforms = platforms.unix;
  78     maintainers = teams.mate.members;
  79   };
  80 }