pkgs/kde/plasma/kinfocenter/default.nix

   1 {
   2   aha,
   3   clinfo,
   4   dmidecode,
   5   iproute2,
   6   lib,
   7   libusb1,
   8   mesa-demos,
   9   mkKdeDerivation,
  10   pciutils,
  11   pulseaudio,
  12   qttools,
  13   substituteAll,
  14   systemsettings,
  15   util-linux,
  16   vulkan-tools,
  17   wayland-utils,
  18   xdpyinfo,
  19 }:
  20 let
  21   tools = {
  22     aha = lib.getExe aha;
  23     clinfo = lib.getExe clinfo;
  24     dmidecode = lib.getExe' dmidecode "dmidecode";
  25     eglinfo = lib.getExe' mesa-demos "eglinfo";
  26     glxinfo = lib.getExe' mesa-demos "glxinfo";
  27     ip = lib.getExe' iproute2 "ip";
  28     lsblk = lib.getExe' util-linux "lsblk";
  29     lspci = lib.getExe' pciutils "lspci";
  30     lscpu = lib.getExe' util-linux "lscpu";
  31     pactl = lib.getExe' pulseaudio "pactl";
  32     qdbus = lib.getExe' qttools "qdbus";
  33     vulkaninfo = lib.getExe' vulkan-tools "vulkaninfo";
  34     waylandinfo = lib.getExe wayland-utils;
  35     xdpyinfo = lib.getExe xdpyinfo;
  36   };
  37 in
  38 mkKdeDerivation {
  39   pname = "kinfocenter";
  40
  41   patches = [
  42     # fwupdmgr is provided through NixOS' module
  43     (substituteAll (
  44       {
  45         src = ./0001-tool-paths.patch;
  46       }
  47       // tools
  48     ))
  49   ];
  50
  51   postPatch = ''
  52     substituteInPlace kcms/firmware_security/fwupdmgr.sh \
  53       --replace-fail " aha " " ${lib.getExe aha} "
  54   '';
  55
  56   extraBuildInputs = [ libusb1 ];
  57
  58   # fix wrong symlink of infocenter pointing to a 'systemsettings5' binary in
  59   # the same directory, while it is actually located in a completely different
  60   # store path
  61   preFixup = ''
  62     ln -sf ${systemsettings}/bin/systemsettings $out/bin/kinfocenter
  63   '';
  64
  65   # Hardcoded as a QString, which is UTF-16 so Nix can't pick it up automatically
  66   postFixup = ''
  67     mkdir -p $out/nix-support
  68     echo "${lib.concatStringsSep ":" (lib.attrValues tools)}" > $out/nix-support/depends
  69   '';
  70
  71   meta.mainProgram = "kinfocenter";
  72 }