pkgs/tools/audio/yabridgectl/default.nix

   1 { lib
   2 , rustPlatform
   3 , yabridge
   4 , makeWrapper
   5 , wine
   6 }:
   7
   8 rustPlatform.buildRustPackage {
   9   pname = "yabridgectl";
  10   version = yabridge.version;
  11
  12   src = yabridge.src;
  13   sourceRoot = "${yabridge.src.name}/tools/yabridgectl";
  14   cargoLock = {
  15     lockFile = ./Cargo.lock;
  16     outputHashes = {
  17       "reflink-0.1.3" = "sha256-1o5d/mepjbDLuoZ2/49Bi6sFgVX4WdCuhGJkk8ulhcI=";
  18     };
  19   };
  20
  21   patches = [
  22     # Patch yabridgectl to search for the chainloader through NIX_PROFILES
  23     ./chainloader-from-nix-profiles.patch
  24
  25     # Dependencies are hardcoded in yabridge, so the check is unnecessary and likely incorrect
  26     ./remove-dependency-verification.patch
  27   ];
  28
  29   patchFlags = [ "-p3" ];
  30
  31   nativeBuildInputs = [ makeWrapper ];
  32
  33   postFixup = ''
  34     wrapProgram "$out/bin/yabridgectl" \
  35       --prefix PATH : ${lib.makeBinPath [
  36         wine # winedump
  37       ]}
  38   '';
  39
  40   meta = with lib; {
  41     description = "Small, optional utility to help set up and update yabridge for several directories at once";
  42     homepage = "${yabridge.src.meta.homepage}/tree/${yabridge.version}/tools/yabridgectl";
  43     changelog = yabridge.meta.changelog;
  44     license = licenses.gpl3Plus;
  45     maintainers = with maintainers; [ kira-bruneau ];
  46     platforms = yabridge.meta.platforms;
  47     mainProgram = "yabridgectl";
  48   };
  49 }