pkgs/tools/backup/bacula/default.nix

   1 { lib, stdenv, fetchurl, sqlite, postgresql, zlib, acl, ncurses, openssl, readline
   2 , gettext, CoreFoundation, IOKit, Kerberos
   3 }:
   4
   5 stdenv.mkDerivation rec {
   6   pname = "bacula";
   7   version = "15.0.2";
   8
   9   src = fetchurl {
  10     url    = "mirror://sourceforge/bacula/${pname}-${version}.tar.gz";
  11     sha256 = "sha256-VVFcKmavmoa5VdrqQIk3i4ZNBRsubjA4O+825pOs6no=";
  12   };
  13
  14   # libtool.m4 only matches macOS 10.*
  15   postPatch = lib.optionalString (stdenv.hostPlatform.isDarwin && stdenv.hostPlatform.isAarch64) ''
  16     substituteInPlace configure \
  17       --replace "10.*)" "*)"
  18   '';
  19
  20   buildInputs = [ postgresql sqlite zlib ncurses openssl readline ]
  21     ++ lib.optionals stdenv.hostPlatform.isDarwin [
  22       gettext # bacula requires CoreFoundation, but its `configure` script will only link it when it detects libintl.
  23       CoreFoundation
  24       IOKit
  25       Kerberos
  26     ]
  27     # acl relies on attr, which I can't get to build on darwin
  28     ++ lib.optional (!stdenv.hostPlatform.isDarwin) acl;
  29
  30   configureFlags = [
  31     "--with-sqlite3=${sqlite.dev}"
  32     "--with-postgresql=${lib.getDev postgresql}"
  33     "--with-logdir=/var/log/bacula"
  34     "--with-working-dir=/var/lib/bacula"
  35     "--mandir=\${out}/share/man"
  36   ] ++ lib.optional (stdenv.buildPlatform != stdenv.hostPlatform) "ac_cv_func_setpgrp_void=yes"
  37     ++ lib.optionals stdenv.isDarwin [
  38       # bacula’s `configure` script fails to detect CoreFoundation correctly,
  39       # but these symbols are available in the nixpkgs CoreFoundation framework.
  40       "gt_cv_func_CFLocaleCopyCurrent=yes"
  41       "gt_cv_func_CFPreferencesCopyAppValue=yes"
  42   ];
  43
  44   installFlags = [
  45     "logdir=\${out}/logdir"
  46     "working_dir=\${out}/workdir"
  47   ];
  48
  49   postInstall = ''
  50     mkdir -p $out/bin
  51     ln -s $out/sbin/* $out/bin
  52   '';
  53
  54   meta = with lib; {
  55     description = "Enterprise ready, Network Backup Tool";
  56     homepage    = "http://bacula.org/";
  57     license     = with licenses; [ agpl3Only bsd2 ];
  58     maintainers = with maintainers; [ lovek323 eleanor ];
  59     platforms   = platforms.all;
  60   };
  61 }