pkgs/tools/graphics/agi/default.nix

   1 { lib
   2 , stdenvNoCC
   3 , fetchzip
   4 , autoPatchelfHook
   5 , makeWrapper
   6 , makeDesktopItem
   7 , copyDesktopItems
   8 , wrapGAppsHook3
   9 , gobject-introspection
  10 , gdk-pixbuf
  11 , jre
  12 , android-tools
  13 }:
  14
  15 stdenvNoCC.mkDerivation rec {
  16   pname = "agi";
  17   version = "3.3.1";
  18
  19   src = fetchzip {
  20     url = "https://github.com/google/agi/releases/download/${version}/agi-${version}-linux.zip";
  21     sha256 = "sha256-Yawl6InBYSWNw3clHyGAeC2PVfXEzWmbd6vcYrqAPO0=";
  22   };
  23
  24   nativeBuildInputs = [
  25     wrapGAppsHook3
  26     gdk-pixbuf
  27     gobject-introspection
  28     autoPatchelfHook
  29     copyDesktopItems
  30     makeWrapper
  31   ];
  32
  33   installPhase = ''
  34     runHook preInstall
  35
  36     mkdir -p $out/bin
  37     cp ./{agi,gapis,gapir,gapit,device-info} $out/bin
  38     cp -r lib $out
  39
  40     for i in 16 32 48 64 96 128 256 512 1024; do
  41       install -D ${src}/icon.png $out/share/icons/hicolor/''${i}x$i/apps/agi.png
  42     done
  43
  44     runHook postInstall
  45   '';
  46
  47   dontWrapGApps = true;
  48
  49   preFixup = ''
  50     wrapProgram $out/bin/agi \
  51       --add-flags "--vm ${jre}/bin/java" \
  52       --add-flags "--adb ${android-tools}/bin/adb" \
  53       --add-flags "--jar $out/lib/gapic.jar" \
  54       "''${gappsWrapperArgs[@]-}"
  55   '';
  56
  57   desktopItems = lib.toList (makeDesktopItem {
  58     name = "agi";
  59     desktopName = "Android GPU Inspector";
  60     exec = "agi";
  61     icon = "agi";
  62     categories = [ "Development" "Debugger" "Graphics" "3DGraphics" ];
  63   });
  64
  65   meta = with lib; {
  66     description = "Android GPU Inspector";
  67     homepage = "https://gpuinspector.dev";
  68     changelog = "https://github.com/google/agi/releases/tag/v${version}";
  69     platforms = [ "x86_64-linux" ];
  70     license = licenses.asl20;
  71     maintainers = with maintainers; [ kashw2 ];
  72     sourceProvenance = with sourceTypes; [
  73       binaryBytecode
  74       binaryNativeCode
  75     ];
  76   };
  77 }