pkgs/tools/graphics/dcraw/default.nix

   1 {lib, stdenv, fetchurl, libjpeg, lcms2, gettext, libiconv }:
   2
   3 stdenv.mkDerivation rec {
   4   pname = "dcraw";
   5   version = "9.28.0";
   6
   7   src = fetchurl {
   8     url = "https://www.dechifro.org/dcraw/archive/dcraw-${version}.tar.gz";
   9     sha256 = "1fdl3xa1fbm71xzc3760rsjkvf0x5jdjrvdzyg2l9ka24vdc7418";
  10   };
  11
  12   nativeBuildInputs = lib.optional stdenv.hostPlatform.isDarwin libiconv;
  13   buildInputs = [ libjpeg lcms2 gettext ];
  14
  15   # Jasper is disabled because the library is abandoned and has many
  16   # CVEs.
  17   patchPhase = ''
  18     substituteInPlace install \
  19       --replace 'prefix=/usr/local' 'prefix=$out' \
  20       --replace gcc '$CC' \
  21       --replace '-ljasper' '-DNO_JASPER=1'
  22   '';
  23
  24   buildPhase = ''
  25     mkdir -p $out/bin
  26     sh -e install
  27   '';
  28
  29   meta = {
  30     homepage = "https://www.dechifro.org/dcraw/";
  31     description = "Decoder for many camera raw picture formats";
  32     license = lib.licenses.free;
  33     platforms = lib.platforms.unix; # Once had cygwin problems
  34     maintainers = [ ];
  35     knownVulnerabilities = [
  36       "CVE-2018-19655"
  37       "CVE-2018-19565"
  38       "CVE-2018-19566"
  39       "CVE-2018-19567"
  40       "CVE-2018-19568"
  41     ];
  42   };
  43 }