pkgs/tools/graphics/fim/default.nix

   1 { gcc9Stdenv, fetchurl, autoconf, automake, pkg-config, lib
   2 , perl, flex, bison, readline, libexif
   3 , x11Support ? true, SDL
   4 , svgSupport ? true, inkscape
   5 , asciiArtSupport ? true, aalib
   6 , gifSupport ? true, giflib
   7 , tiffSupport ? true, libtiff
   8 , jpegSupport ? true, libjpeg
   9 , pngSupport ? true, libpng
  10 }:
  11
  12 gcc9Stdenv.mkDerivation rec {
  13   pname = "fim";
  14   version = "0.7";
  15
  16   src = fetchurl {
  17     url = "mirror://savannah/fbi-improved/${pname}-${version}-trunk.tar.gz";
  18     sha256 = "sha256-/p7bjeZM46DJOQ9sgtebhkNpBPj2RJYY3dMXhzHnNmg=";
  19   };
  20
  21   postPatch = ''
  22    substituteInPlace doc/vim2html.pl \
  23      --replace /usr/bin/perl ${perl}/bin/perl
  24   '';
  25
  26   nativeBuildInputs = [ autoconf automake pkg-config ];
  27
  28   buildInputs =
  29     [ perl flex bison readline libexif ]
  30     ++ lib.optional x11Support SDL
  31     ++ lib.optional svgSupport inkscape
  32     ++ lib.optional asciiArtSupport aalib
  33     ++ lib.optional gifSupport giflib
  34     ++ lib.optional tiffSupport libtiff
  35     ++ lib.optional jpegSupport libjpeg
  36     ++ lib.optional pngSupport libpng;
  37
  38   env.NIX_CFLAGS_COMPILE = lib.optionalString x11Support "-lSDL";
  39
  40   meta = with lib; {
  41     description = "Lightweight, highly customizable and scriptable image viewer";
  42     longDescription = ''
  43       FIM (Fbi IMproved) is a lightweight, console based image viewer that aims
  44       to be a highly customizable and scriptable for users who are comfortable
  45       with software like the VIM text editor or the Mutt mail user agent.
  46     '';
  47     homepage = "https://www.nongnu.org/fbi-improved/";
  48     license = licenses.gpl2Plus;
  49     platforms = platforms.linux;
  50     maintainers = with maintainers; [ primeos ];
  51   };
  52 }