pkgs/tools/inputmethods/ibus/default.nix

   1 { lib
   2 , stdenv
   3 , substituteAll
   4 , fetchFromGitHub
   5 , autoreconfHook
   6 , gettext
   7 , makeWrapper
   8 , pkg-config
   9 , vala
  10 , wrapGAppsHook3
  11 , dbus
  12 , systemd
  13 , dconf ? null
  14 , glib
  15 , gdk-pixbuf
  16 , gobject-introspection
  17 , gtk3
  18 , gtk4
  19 , gtk-doc
  20 , libdbusmenu-gtk3
  21 , runCommand
  22 , isocodes
  23 , cldr-annotations
  24 , unicode-character-database
  25 , unicode-emoji
  26 , python3
  27 , json-glib
  28 , libnotify ? null
  29 , enableUI ? true
  30 , withWayland ? true
  31 , libxkbcommon
  32 , wayland
  33 , buildPackages
  34 , runtimeShell
  35 , nixosTests
  36 }:
  37
  38 let
  39   python3Runtime = python3.withPackages (ps: with ps; [ pygobject3 ]);
  40   python3BuildEnv = python3.buildEnv.override {
  41     # ImportError: No module named site
  42     postBuild = ''
  43       makeWrapper ${glib.dev}/bin/gdbus-codegen $out/bin/gdbus-codegen --unset PYTHONPATH
  44       makeWrapper ${glib.dev}/bin/glib-genmarshal $out/bin/glib-genmarshal --unset PYTHONPATH
  45       makeWrapper ${glib.dev}/bin/glib-mkenums $out/bin/glib-mkenums --unset PYTHONPATH
  46     '';
  47   };
  48   # make-dconf-override-db.sh needs to execute dbus-launch in the sandbox,
  49   # it will fail to read /etc/dbus-1/session.conf unless we add this flag
  50   dbus-launch = runCommand "sandbox-dbus-launch"
  51     {
  52       nativeBuildInputs = [ makeWrapper ];
  53     } ''
  54     makeWrapper ${dbus}/bin/dbus-launch $out/bin/dbus-launch \
  55       --add-flags --config-file=${dbus}/share/dbus-1/session.conf
  56   '';
  57 in
  58
  59 stdenv.mkDerivation rec {
  60   pname = "ibus";
  61   version = "1.5.30";
  62
  63   src = fetchFromGitHub {
  64     owner = "ibus";
  65     repo = "ibus";
  66     rev = version;
  67     sha256 = "sha256-VgSjeKF9DCkDfE9lHEaWpgZb6ibdgoDf/I6qeJf8Ah4=";
  68   };
  69
  70   patches = [
  71     (substituteAll {
  72       src = ./fix-paths.patch;
  73       pythonInterpreter = python3Runtime.interpreter;
  74       pythonSitePackages = python3.sitePackages;
  75     })
  76     ./build-without-dbus-launch.patch
  77   ];
  78
  79   outputs = [ "out" "dev" "installedTests" ];
  80
  81   postPatch = ''
  82     # Maintainer does not want to create separate tarballs for final release candidate and release versions,
  83     # so we need to set `ibus_released` to `1` in `configure.ac`. Otherwise, anyone running `ibus version` gets
  84     # a version with an inaccurate `-rcX` suffix.
  85     # https://github.com/ibus/ibus/issues/2584
  86     substituteInPlace configure.ac --replace "m4_define([ibus_released], [0])" "m4_define([ibus_released], [1])"
  87
  88     patchShebangs --build data/dconf/make-dconf-override-db.sh
  89     cp ${buildPackages.gtk-doc}/share/gtk-doc/data/gtk-doc.make .
  90     substituteInPlace bus/services/org.freedesktop.IBus.session.GNOME.service.in --replace "ExecStart=sh" "ExecStart=${runtimeShell}"
  91     substituteInPlace bus/services/org.freedesktop.IBus.session.generic.service.in --replace "ExecStart=sh" "ExecStart=${runtimeShell}"
  92   '';
  93
  94   preAutoreconf = "touch ChangeLog";
  95
  96   configureFlags = [
  97     # The `AX_PROG_{CC,CXX}_FOR_BUILD` autoconf macros can pick up unwrapped GCC binaries,
  98     # so we set `{CC,CXX}_FOR_BUILD` to override that behavior.
  99     # https://github.com/NixOS/nixpkgs/issues/21751
 100     "CC_FOR_BUILD=${stdenv.cc}/bin/cc"
 101     "CXX_FOR_BUILD=${stdenv.cc}/bin/c++"
 102     "--disable-memconf"
 103     (lib.enableFeature (dconf != null) "dconf")
 104     (lib.enableFeature (libnotify != null) "libnotify")
 105     (lib.enableFeature withWayland "wayland")
 106     (lib.enableFeature enableUI "ui")
 107     "--disable-gtk2"
 108     "--enable-gtk4"
 109     "--enable-install-tests"
 110     "--with-unicode-emoji-dir=${unicode-emoji}/share/unicode/emoji"
 111     "--with-emoji-annotation-dir=${cldr-annotations}/share/unicode/cldr/common/annotations"
 112     "--with-ucd-dir=${unicode-character-database}/share/unicode"
 113   ];
 114
 115   makeFlags = [
 116     "test_execsdir=${placeholder "installedTests"}/libexec/installed-tests/ibus"
 117     "test_sourcesdir=${placeholder "installedTests"}/share/installed-tests/ibus"
 118   ];
 119
 120   nativeBuildInputs = [
 121     autoreconfHook
 122     gtk-doc
 123     gettext
 124     makeWrapper
 125     pkg-config
 126     python3BuildEnv
 127     vala
 128     wrapGAppsHook3
 129     dbus-launch
 130     gobject-introspection
 131   ];
 132
 133   propagatedBuildInputs = [
 134     glib
 135   ];
 136
 137   buildInputs = [
 138     dbus
 139     systemd
 140     dconf
 141     gdk-pixbuf
 142     python3.pkgs.pygobject3 # for pygobject overrides
 143     gtk3
 144     gtk4
 145     isocodes
 146     json-glib
 147     libnotify
 148     libdbusmenu-gtk3
 149   ] ++ lib.optionals withWayland [
 150     libxkbcommon
 151     wayland
 152   ];
 153
 154   enableParallelBuilding = true;
 155
 156   doCheck = false; # requires X11 daemon
 157   doInstallCheck = true;
 158   installCheckPhase = ''
 159     $out/bin/ibus version
 160   '';
 161
 162   postInstall = ''
 163     # It has some hardcoded FHS paths and also we do not use it
 164     # since we set up the environment in NixOS tests anyway.
 165     moveToOutput "bin/ibus-desktop-testing-runner" "$installedTests"
 166   '';
 167
 168   postFixup = ''
 169     # set necessary environment also for tests
 170     for f in $installedTests/libexec/installed-tests/ibus/*; do
 171         wrapGApp $f
 172     done
 173   '';
 174
 175   passthru = {
 176     tests = {
 177       installed-tests = nixosTests.installed-tests.ibus;
 178     };
 179   };
 180
 181   meta = with lib; {
 182     homepage = "https://github.com/ibus/ibus";
 183     description = "Intelligent Input Bus, input method framework";
 184     license = licenses.lgpl21Plus;
 185     platforms = platforms.linux;
 186     maintainers = with maintainers; [ ttuegel ];
 187   };
 188 }