pkgs/tools/misc/daktilo/default.nix

   1 { lib
   2 , rustPlatform
   3 , fetchFromGitHub
   4 , installShellFiles
   5 , stdenv
   6 , darwin
   7 , unixtools
   8 , pkg-config
   9 , alsa-lib
  10 , xorg
  11 }:
  12
  13 rustPlatform.buildRustPackage rec {
  14   pname = "daktilo";
  15   version = "0.6.0";
  16
  17   src = fetchFromGitHub {
  18     owner = "orhun";
  19     repo = "daktilo";
  20     rev = "v${version}";
  21     hash = "sha256-gIBWonJGX6IpxyBeMulcfQEExsG1GrBVQLZbBBA1ruc=";
  22   };
  23
  24   cargoHash = "sha256-lBlzXTkhsEboTby5tH7WfsvZxUwtw7sLYVJRozjI1D4=";
  25
  26   nativeBuildInputs = [
  27     installShellFiles
  28     pkg-config
  29   ];
  30
  31   buildInputs = [
  32     alsa-lib
  33     xorg.libX11
  34     xorg.libXi
  35     xorg.libXtst
  36   ] ++ lib.optionals stdenv.hostPlatform.isDarwin [
  37     darwin.apple_sdk.frameworks.Security
  38   ];
  39
  40   nativeCheckInputs = [
  41     unixtools.script
  42   ];
  43
  44   postInstall = ''
  45     mkdir -p man completions
  46
  47     OUT_DIR=man $out/bin/daktilo-mangen
  48     OUT_DIR=completions $out/bin/daktilo-completions
  49
  50     installManPage man/daktilo.1
  51     installShellCompletion \
  52       completions/daktilo.{bash,fish} \
  53       --zsh completions/_daktilo
  54
  55     rm $out/bin/daktilo-{completions,mangen}
  56   '';
  57
  58   meta = with lib; {
  59     description = "Turn your keyboard into a typewriter";
  60     homepage = "https://github.com/orhun/daktilo";
  61     changelog = "https://github.com/orhun/daktilo/blob/${src.rev}/CHANGELOG.md";
  62     license = with licenses; [ asl20 mit ];
  63     maintainers = with maintainers; [ orhun ];
  64     mainProgram = "daktilo";
  65   };
  66 }