pkgs/tools/misc/hdf5/default.nix

   1 { lib
   2 , stdenv
   3 , fetchFromGitHub
   4 , cmake
   5 , removeReferencesTo
   6 , cppSupport ? true
   7 , fortranSupport ? false
   8 , fortran
   9 , zlibSupport ? true
  10 , zlib
  11 , szipSupport ? false
  12 , szip
  13 , mpiSupport ? false
  14 , mpi
  15 , enableShared ? !stdenv.hostPlatform.isStatic
  16 , enableStatic ? stdenv.hostPlatform.isStatic
  17 , javaSupport ? false
  18 , jdk
  19 , usev110Api ? false
  20 , threadsafe ? false
  21 , python3
  22 }:
  23
  24 # cpp and mpi options are mutually exclusive
  25 # (--enable-unsupported could be used to force the build)
  26 assert !cppSupport || !mpiSupport;
  27
  28 let inherit (lib) optional optionals; in
  29
  30 stdenv.mkDerivation rec {
  31   version = "1.14.4.3";
  32   pname = "hdf5"
  33     + lib.optionalString cppSupport "-cpp"
  34     + lib.optionalString fortranSupport "-fortran"
  35     + lib.optionalString mpiSupport "-mpi"
  36     + lib.optionalString threadsafe "-threadsafe";
  37
  38   src = fetchFromGitHub {
  39     owner = "HDFGroup";
  40     repo = "hdf5";
  41     rev = "hdf5_${version}";
  42     hash = "sha256-lvz3x04SS0oZmUn/BIxQEHnugaDOws46kfT3NAw7Hos=";
  43   };
  44
  45   passthru = {
  46     inherit
  47       cppSupport
  48       fortranSupport
  49       fortran
  50       zlibSupport
  51       zlib
  52       szipSupport
  53       szip
  54       mpiSupport
  55       mpi
  56       ;
  57   };
  58
  59   outputs = [ "out" "dev" "bin" ];
  60
  61   nativeBuildInputs = [ removeReferencesTo cmake ]
  62     ++ optional fortranSupport fortran;
  63
  64   buildInputs = optional fortranSupport fortran
  65     ++ optional szipSupport szip
  66     ++ optional javaSupport jdk;
  67
  68   propagatedBuildInputs = optional zlibSupport zlib
  69     ++ optional mpiSupport mpi;
  70
  71   cmakeFlags = [
  72     "-DHDF5_INSTALL_CMAKE_DIR=${placeholder "dev"}/lib/cmake"
  73     "-DBUILD_STATIC_LIBS=${lib.boolToString enableStatic}"
  74   ] ++ lib.optional stdenv.hostPlatform.isDarwin "-DHDF5_BUILD_WITH_INSTALL_NAME=ON"
  75     ++ lib.optional cppSupport "-DHDF5_BUILD_CPP_LIB=ON"
  76     ++ lib.optional fortranSupport "-DHDF5_BUILD_FORTRAN=ON"
  77     ++ lib.optional szipSupport "-DHDF5_ENABLE_SZIP_SUPPORT=ON"
  78     ++ lib.optionals mpiSupport [ "-DHDF5_ENABLE_PARALLEL=ON" ]
  79     ++ lib.optional enableShared "-DBUILD_SHARED_LIBS=ON"
  80     ++ lib.optional javaSupport "-DHDF5_BUILD_JAVA=ON"
  81     ++ lib.optional usev110Api "-DDEFAULT_API_VERSION=v110"
  82     ++ lib.optionals threadsafe [ "-DDHDF5_ENABLE_THREADSAFE:BOOL=ON" "-DHDF5_BUILD_HL_LIB=OFF" ]
  83     # broken in nixpkgs since around 1.14.3 -> 1.14.4.3
  84     # https://github.com/HDFGroup/hdf5/issues/4208#issuecomment-2098698567
  85     ++ lib.optional (stdenv.hostPlatform.isDarwin && stdenv.hostPlatform.isx86_64) "-DHDF5_ENABLE_NONSTANDARD_FEATURE_FLOAT16=OFF"
  86   ;
  87
  88   postInstall = ''
  89     find "$out" -type f -exec remove-references-to -t ${stdenv.cc} '{}' +
  90     moveToOutput 'bin/' "''${!outputBin}"
  91     moveToOutput 'bin/h5cc' "''${!outputDev}"
  92     moveToOutput 'bin/h5c++' "''${!outputDev}"
  93     moveToOutput 'bin/h5fc' "''${!outputDev}"
  94     moveToOutput 'bin/h5pcc' "''${!outputDev}"
  95     moveToOutput 'bin/h5hlcc' "''${!outputDev}"
  96     moveToOutput 'bin/h5hlc++' "''${!outputDev}"
  97   '' + lib.optionalString enableShared
  98   # The shared build creates binaries with -shared suffixes,
  99   # so we remove these suffixes.
 100   ''
 101     pushd ''${!outputBin}/bin
 102     for file in *-shared; do
 103       mv "$file" "''${file%%-shared}"
 104     done
 105     popd
 106   '' + lib.optionalString fortranSupport
 107   ''
 108     mv $out/mod/shared $dev/include
 109     rm -r $out/mod
 110
 111     find "$out" -type f -exec remove-references-to -t ${fortran} '{}' +
 112   '';
 113
 114   enableParallelBuilding = true;
 115
 116   passthru.tests = {
 117     inherit (python3.pkgs) h5py;
 118   };
 119
 120   meta = with lib; {
 121     description = "Data model, library, and file format for storing and managing data";
 122     longDescription = ''
 123       HDF5 supports an unlimited variety of datatypes, and is designed for flexible and efficient
 124       I/O and for high volume and complex data. HDF5 is portable and is extensible, allowing
 125       applications to evolve in their use of HDF5. The HDF5 Technology suite includes tools and
 126       applications for managing, manipulating, viewing, and analyzing data in the HDF5 format.
 127     '';
 128     license = licenses.bsd3; # Lawrence Berkeley National Labs BSD 3-Clause variant
 129     maintainers = [ maintainers.markuskowa ];
 130     homepage = "https://www.hdfgroup.org/HDF5/";
 131     platforms = platforms.unix;
 132   };
 133 }