pkgs/tools/misc/lbdb/default.nix

   1 { lib
   2 , stdenv
   3 , fetchurl
   4 , fetchpatch
   5 , perl
   6 , bsd-finger
   7 , withAbook ? true, abook
   8 , withGnupg ? true, gnupg
   9 , withGoobook ? true, goobook
  10 , withKhard ? true, khard
  11 , withMu ? true, mu
  12 }:
  13
  14 let
  15   perl' = perl.withPackages (p: with p; [
  16     AuthenSASL
  17     ConvertASN1
  18     IOSocketSSL
  19     perlldap
  20   ]);
  21 in
  22 stdenv.mkDerivation rec {
  23   pname = "lbdb";
  24   version = "0.48.1";
  25
  26   src = fetchurl {
  27     url = "https://www.spinnaker.de/lbdb/download/lbdb_${version}.tar.gz";
  28     sha256 = "1gr5l2fr9qbdccga8bhsrpvz6jxigvfkdxrln9wyf2xpps5cdjxh";
  29   };
  30
  31   buildInputs = [ perl' ]
  32     ++ lib.optional (!stdenv.hostPlatform.isDarwin) bsd-finger
  33     ++ lib.optional withAbook abook
  34     ++ lib.optional withGnupg gnupg
  35     ++ lib.optional withGoobook goobook
  36     ++ lib.optional withKhard khard
  37     ++ lib.optional withMu mu;
  38
  39   configureFlags = [ ]
  40     ++ lib.optional withAbook "--with-abook"
  41     ++ lib.optional withGnupg "--with-gpg"
  42     ++ lib.optional withGoobook "--with-goobook"
  43     ++ lib.optional withKhard "--with-khard"
  44     ++ lib.optional withMu "--with-mu";
  45
  46   patches = [
  47     ./add-methods-to-rc.patch
  48     # fix undefined exec_prefix. Remove with the next release
  49     (fetchpatch {
  50       url = "https://github.com/RolandRosenfeld/lbdb/commit/60b7bae255011f59212d96adfbded459d6a27129.patch";
  51       sha256 = "129zg086glmlalrg395jq8ljcp787dl3rxjf9v7apsd8mqfdkl2v";
  52       excludes = [ "debian/changelog" ];
  53     })
  54   ];
  55
  56   meta = with lib; {
  57     homepage = "https://www.spinnaker.de/lbdb/";
  58     description = "Little Brother's Database";
  59     license = licenses.gpl2Plus;
  60     maintainers = with maintainers; [ kaiha bfortz ];
  61     platforms = platforms.all;
  62   };
  63 }