pkgs/tools/misc/ocs-url/default.nix

   1 { lib, stdenv, fetchgit, libsForQt5 }:
   2
   3 let
   4   version = "3.1.0";
   5
   6   main_src = fetchgit {
   7     url = "https://www.opencode.net/dfn2/ocs-url.git";
   8     rev = "release-${version}";
   9     sha256 = "RvbkcSj8iUAHAEOyETwfH+3XnCCY/p8XM8LgVrZxrws=";
  10   };
  11
  12   qtil_src = fetchgit {
  13     url = "https://github.com/akiraohgaki/qtil";
  14     rev = "v0.4.0";
  15     sha256 = "XRSp0F7ggfkof1RNAnQU3+O9DcXDy81VR7NakITOXrw=";
  16   };
  17 in
  18
  19 stdenv.mkDerivation rec {
  20   pname = "ocs-url";
  21   inherit version;
  22
  23   srcs = [ main_src qtil_src ];
  24   sourceRoot = main_src.name;
  25
  26   # We are NOT in $sourceRoot here
  27   postUnpack = ''
  28     mkdir -p $sourceRoot/lib/qtil
  29     cp -r ${qtil_src.name}/* $sourceRoot/lib/qtil/
  30   '';
  31
  32   buildInputs = with libsForQt5.qt5; [
  33     qtbase
  34     qtsvg
  35     qtquickcontrols
  36     qmake
  37     wrapQtAppsHook
  38   ];
  39
  40   meta = with lib; {
  41     description = "Open Collaboration System for use with DE store websites";
  42     license = licenses.gpl3Only;
  43     maintainers = with maintainers; [ SohamG ];
  44     platforms = platforms.linux;
  45     mainProgram = "ocs-url";
  46   };
  47 }