pkgs/tools/misc/tldr/default.nix

   1 { lib, stdenv, fetchFromGitHub, curl, libzip, pkg-config, installShellFiles }:
   2
   3 stdenv.mkDerivation rec {
   4   pname = "tldr";
   5   version = "1.6.1";
   6
   7   src = fetchFromGitHub {
   8     owner = "tldr-pages";
   9     repo = "tldr-c-client";
  10     rev = "v${version}";
  11     sha256 = "sha256-1L9frURnzfq0XvPBs8D+hBikybAw8qkb0DyZZtkZleY=";
  12   };
  13
  14   buildInputs = [ curl libzip ];
  15   nativeBuildInputs = [ pkg-config installShellFiles ];
  16
  17   makeFlags = ["CC=${stdenv.cc.targetPrefix}cc" "LD=${stdenv.cc.targetPrefix}cc" "CFLAGS="];
  18
  19   installFlags = [ "PREFIX=$(out)" ];
  20
  21   postInstall = ''
  22     installShellCompletion --cmd tldr autocomplete/complete.{bash,fish,zsh}
  23   '';
  24
  25   meta = with lib; {
  26     description = "Simplified and community-driven man pages";
  27     longDescription = ''
  28       tldr pages gives common use cases for commands, so you don't need to hunt
  29       through a man page for the correct flags.
  30     '';
  31     homepage = "https://tldr.sh";
  32     changelog = "https://github.com/tldr-pages/tldr-c-client/blob/v${version}/CHANGELOG.md";
  33     license = licenses.mit;
  34     maintainers = with maintainers; [ taeer carlosdagos kbdharun];
  35     platforms = platforms.all;
  36     mainProgram = "tldr";
  37   };
  38 }