pkgs/tools/misc/wv/default.nix

   1 { lib, stdenv, fetchFromGitHub, zlib, imagemagick, libpng, glib, pkg-config, libgsf
   2 , libxml2, bzip2
   3 , autoreconfHook
   4 , buildPackages
   5 }:
   6
   7 stdenv.mkDerivation (finalAttrs: {
   8   pname = "wv";
   9   version = "1.2.9";
  10
  11   src = fetchFromGitHub {
  12     owner = "AbiWord";
  13     repo = "wv";
  14     rev = "wv-${builtins.replaceStrings ["."] ["-"] finalAttrs.version}";
  15     hash = "sha256-xcC+/M1EzFqQFeF5Dw9qd8VIy7r8JdKMp2X/GHkFiPA=";
  16   };
  17
  18   nativeBuildInputs = [ pkg-config autoreconfHook ];
  19   buildInputs = [ zlib imagemagick libpng glib libgsf libxml2 bzip2 ];
  20
  21   configureFlags = [
  22     "PKG_CONFIG=${buildPackages.pkg-config}/bin/${buildPackages.pkg-config.targetPrefix}pkg-config"
  23   ];
  24
  25   env.NIX_CFLAGS_COMPILE =
  26     # Suppress incompatible function pointer and int conversion errors when building with newer versions of clang 16.
  27     lib.optionalString stdenv.cc.isClang "-Wno-error=incompatible-function-pointer-types -Wno-error=int-conversion";
  28
  29   hardeningDisable = [ "format" ];
  30
  31   enableParallelBuilding = true;
  32
  33   # autoreconfHook fails hard if these two files do not exist.
  34   # The extra move is to work around case-insensitive filesystems.
  35   postPatch = ''
  36     touch AUTHORS
  37     mv CHANGELOG ChangeLog~ && mv ChangeLog~ ChangeLog
  38   '';
  39
  40   meta = {
  41     homepage = "https://github.com/AbiWord/wv";
  42     description = "Converter from Microsoft Word formats to human-editable ones";
  43     platforms = lib.platforms.unix;
  44     license = lib.licenses.gpl2Plus;
  45   };
  46 })