pkgs/tools/networking/openssh/default.nix

   1 { callPackage, lib, fetchurl, fetchpatch, autoreconfHook }:
   2 let
   3   common = opts: callPackage (import ./common.nix opts) { };
   4 in
   5 {
   6   openssh = common rec {
   7     pname = "openssh";
   8     version = "9.8p1";
   9
  10     src = fetchurl {
  11       url = "mirror://openbsd/OpenSSH/portable/openssh-${version}.tar.gz";
  12       hash = "sha256-3YvQAqN5tdSZ37BQ3R+pr4Ap6ARh9LtsUjxJlz9aOfM=";
  13     };
  14
  15     extraPatches = [ ./ssh-keysign-8.5.patch ];
  16     extraMeta.maintainers = lib.teams.helsinki-systems.members;
  17   };
  18
  19   openssh_hpn = common rec {
  20     pname = "openssh-with-hpn";
  21     version = "9.8p1";
  22     extraDesc = " with high performance networking patches";
  23
  24     src = fetchurl {
  25       url = "mirror://openbsd/OpenSSH/portable/openssh-${version}.tar.gz";
  26       hash = "sha256-3YvQAqN5tdSZ37BQ3R+pr4Ap6ARh9LtsUjxJlz9aOfM=";
  27     };
  28
  29     extraPatches = let url = "https://raw.githubusercontent.com/freebsd/freebsd-ports/7ba88c964b6e5724eec462021d984da3989e6a08/security/openssh-portable/files/extra-patch-hpn"; in
  30     [
  31       ./ssh-keysign-8.5.patch
  32
  33       # HPN Patch from FreeBSD ports
  34       (fetchpatch {
  35         name = "ssh-hpn-wo-channels.patch";
  36         inherit url;
  37         stripLen = 1;
  38         excludes = [ "channels.c" ];
  39         hash = "sha256-zk7t6FNzTE+8aDU4QuteR1x0W3O2gjIQmeCkTNbaUfA=";
  40       })
  41
  42       (fetchpatch {
  43         name = "ssh-hpn-channels.patch";
  44         inherit url;
  45         extraPrefix = "";
  46         includes = [ "channels.c" ];
  47         hash = "sha256-pDLUbjv5XIyByEbiRAXC3WMUPKmn15af1stVmcvr7fE=";
  48       })
  49     ];
  50
  51     extraNativeBuildInputs = [ autoreconfHook ];
  52
  53     extraConfigureFlags = [ "--with-hpn" ];
  54     extraMeta = {
  55       maintainers = with lib.maintainers; [ abbe ];
  56     };
  57   };
  58
  59   openssh_gssapi = common rec {
  60     pname = "openssh-with-gssapi";
  61     version = "9.8p1";
  62     extraDesc = " with GSSAPI support";
  63
  64     src = fetchurl {
  65       url = "mirror://openbsd/OpenSSH/portable/openssh-${version}.tar.gz";
  66       hash = "sha256-3YvQAqN5tdSZ37BQ3R+pr4Ap6ARh9LtsUjxJlz9aOfM=";
  67     };
  68
  69     extraPatches = [
  70       ./ssh-keysign-8.5.patch
  71
  72       (fetchpatch {
  73         name = "openssh-gssapi.patch";
  74         url = "https://salsa.debian.org/ssh-team/openssh/raw/debian/1%25${version}-3/debian/patches/gssapi.patch";
  75         hash = "sha256-BnmEZ5pMIbbysesMSm54ykdweH4JudM9D4Pn5uWf3EY=";
  76       })
  77     ];
  78
  79     extraNativeBuildInputs = [ autoreconfHook ];
  80   };
  81 }