pkgs/tools/networking/reaver-wps/default.nix

   1 { lib, stdenv, fetchurl, libpcap, sqlite, makeWrapper }:
   2
   3 stdenv.mkDerivation rec {
   4   version = "1.4";
   5   pname = "reaver-wps";
   6   confdir = "/var/db/${pname}-${version}"; # the sqlite database is at "${confdir}/reaver/reaver.db"
   7
   8   src = fetchurl {
   9     url = "https://storage.googleapis.com/google-code-archive-downloads/v2/code.google.com/reaver-wps/reaver-${version}.tar.gz";
  10     sha256 = "0bdjai4p8xbsw8zdkkk43rgsif79x0nyx4djpyv0mzh59850blxd";
  11   };
  12
  13   nativeBuildInputs = [ makeWrapper ];
  14   buildInputs = [ libpcap sqlite ];
  15
  16   # Workaround build failure on -fno-common toolchains:
  17   #   ld: crypto/dh_groups.o:src/crypto/../globule.h:141: multiple definition of
  18   #     `globule'; /build/ccrzO6vA.o:src/globule.h:141: first defined here
  19   env.NIX_CFLAGS_COMPILE = "-fcommon";
  20
  21   setSourceRoot = ''
  22     sourceRoot=$(echo */src)
  23   '';
  24
  25   configureFlags = [ "--sysconfdir=${confdir}" ];
  26
  27   installPhase = ''
  28     mkdir -p $out/{bin,etc}
  29     cp reaver.db $out/etc/
  30     cp reaver wash $out/bin/
  31
  32     wrapProgram $out/bin/reaver --run "[ -s ${confdir}/reaver/reaver.db ] || install -D $out/etc/reaver.db ${confdir}/reaver/reaver.db"
  33     wrapProgram $out/bin/wash   --run "[ -s ${confdir}/reaver/reaver.db ] || install -D $out/etc/reaver.db ${confdir}/reaver/reaver.db"
  34   '';
  35
  36   enableParallelBuilding = true;
  37
  38   patches = [ ./parallel-build.patch ];
  39
  40   meta = with lib; {
  41     description = "Brute force attack against Wifi Protected Setup";
  42     homepage = "https://code.google.com/archive/p/reaver-wps/";
  43     license = licenses.gpl2Plus;
  44     platforms = platforms.linux;
  45     maintainers = with maintainers; [ nico202 ];
  46   };
  47 }