pkgs/tools/nix/npins/default.nix

   1 { lib
   2 , rustPlatform
   3 , makeWrapper
   4 , stdenv
   5 , darwin
   6 , callPackage
   7
   8   # runtime dependencies
   9 , nix # for nix-prefetch-url
  10 , nix-prefetch-git
  11 , git # for git ls-remote
  12 }:
  13
  14 let
  15   runtimePath = lib.makeBinPath [ nix nix-prefetch-git git ];
  16   sources = (lib.importJSON ./sources.json).pins;
  17 in rustPlatform.buildRustPackage rec {
  18   pname = "npins";
  19   version = src.version;
  20   src = passthru.mkSource sources.npins;
  21
  22   cargoHash = "sha256-YwMypBl+P1ygf4zUbkZlq4zPrOzf+lPOz2FLg2/xI3k=";
  23
  24   buildInputs = lib.optional stdenv.hostPlatform.isDarwin (with darwin.apple_sdk.frameworks; [ Security SystemConfiguration ]);
  25   nativeBuildInputs = [ makeWrapper ];
  26
  27   # (Almost) all tests require internet
  28   doCheck = false;
  29
  30   postFixup = ''
  31     wrapProgram $out/bin/npins --prefix PATH : "${runtimePath}"
  32   '';
  33
  34   meta = with lib; {
  35     description = "Simple and convenient dependency pinning for Nix";
  36     mainProgram = "npins";
  37     homepage = "https://github.com/andir/npins";
  38     license = licenses.eupl12;
  39     maintainers = with maintainers; [ piegames ];
  40   };
  41
  42   passthru.mkSource = callPackage ./source.nix {};
  43 }