pkgs/tools/system/dell-command-configure/default.nix

   1 {
   2   stdenv,
   3   lib,
   4   fetchurl,
   5   dpkg,
   6   autoPatchelfHook,
   7   patchelfUnstable,
   8   openssl,
   9 }:
  10
  11 # Use techniques described in https://web.archive.org/web/20220904051329/https://tapesoftware.net/replace-symbol/
  12
  13 # Adapted from https://github.com/KenMacD/etc-nixos/blob/d3d28085586358a62b2bb4b427eb21aad05b5b23/dcc/default.nix
  14
  15 # Used https://github.com/NixOS/nixpkgs/pull/84926 as a template
  16 # then converted to use autoPatchelfHook instead, and link with
  17 # the dependencies from other pkgs.
  18
  19 let
  20   version = "4.11.0-6";
  21
  22   unpacked = stdenv.mkDerivation rec {
  23     inherit version;
  24     pname = "dell-command-configure-unpacked";
  25
  26     src = fetchurl {
  27       urls = [
  28         "https://dl.dell.com/FOLDER10469726M/1/command-configure_${version}.ubuntu22_amd64.tar.gz"
  29         "https://web.archive.org/web/20240228233129/https://dl.dell.com/FOLDER10469726M/1/command-configure_4.11.0-6.ubuntu22_amd64.tar.gz"
  30       ];
  31       # The CDN blocks the Curl user-agent, so set to blank instead.
  32       curlOpts = ''-A=""'';
  33       hash = "sha256-Bwa4sYguYwEBKEJSP3wzHhzjuDeaGQN8fKeooWHX18E=";
  34     };
  35
  36     dontBuild = true;
  37
  38     nativeBuildInputs = [ dpkg ];
  39
  40     unpackPhase = ''
  41       tar -xzf ${src}
  42       dpkg-deb -x command-configure_${version}.ubuntu22_amd64.deb command-configure
  43       dpkg-deb -x srvadmin-hapi_9.5.0_amd64.deb srvadmin-hapi
  44     '';
  45
  46     installPhase = ''
  47       mkdir $out
  48       cp -r . $out
  49     '';
  50   };
  51
  52   # Contains a fopen() wrapper for finding the firmware package
  53   wrapperLibName = "wrapper-lib.so";
  54   wrapperLib = stdenv.mkDerivation {
  55     pname = "dell-command-configure-unpacked-wrapper-lib";
  56     inherit version;
  57
  58     unpackPhase = ''
  59       cp ${./wrapper-lib.c} wrapper-lib.c
  60     '';
  61
  62     postPatch = ''
  63       substitute wrapper-lib.c lib.c \
  64         --subst-var-by to "${unpacked}/srvadmin-hapi/opt/dell/srvadmin/etc/omreg.d/omreg-hapi.cfg"
  65       cc -fPIC -shared lib.c -o ${wrapperLibName}
  66     '';
  67     installPhase = ''
  68       install -D ${wrapperLibName} -t $out/lib
  69     '';
  70   };
  71
  72 in stdenv.mkDerivation rec {
  73   inherit version;
  74   pname = "dell-command-configure";
  75
  76   buildInputs = [ openssl stdenv.cc.cc.lib ];
  77   nativeBuildInputs = [ autoPatchelfHook ];
  78   dontConfigure = true;
  79
  80   src = unpacked;
  81
  82   installPhase = ''
  83     install -D -t $out/lib -m644 -v command-configure/opt/dell/dcc/libhapiintf.so
  84     install -D -t $out/lib -m644 -v command-configure/opt/dell/dcc/libsmbios_c.so.2
  85     install -D -t $out/bin -m755 -v command-configure/opt/dell/dcc/cctk
  86     install -D -t $out/bin -m755 -v srvadmin-hapi/opt/dell/srvadmin/sbin/dchcfg
  87     for lib in $(find srvadmin-hapi/opt/dell/srvadmin/lib64 -type l); do
  88         install -D -t $out/lib -m644 -v $lib
  89     done
  90   '';
  91
  92   postFixup = ''
  93     echo fopen fopen_wrapper > fopen_name_map
  94     echo access access_wrapper > access_name_map
  95     ${patchelfUnstable}/bin/patchelf \
  96       --rename-dynamic-symbols fopen_name_map \
  97       --rename-dynamic-symbols access_name_map \
  98       --add-needed ${wrapperLibName} \
  99       --set-rpath ${lib.makeLibraryPath [ wrapperLib ]} \
 100       $out/lib/*
 101   '';
 102
 103   meta = with lib; {
 104     description = "Configure BIOS settings on Dell laptops";
 105     homepage =
 106       "https://www.dell.com/support/article/us/en/19/sln311302/dell-command-configure";
 107     license = licenses.unfree;
 108     maintainers = with maintainers; [ ryangibb ];
 109     platforms = [ "x86_64-linux" ];
 110   };
 111 }