pkgs/applications/file-managers/lf/ctpv.nix

   1 { lib
   2 , stdenv
   3 , fetchFromGitHub
   4 , makeWrapper
   5 , file
   6 , openssl
   7 , atool
   8 , bat
   9 , chafa
  10 , delta
  11 , ffmpeg
  12 , ffmpegthumbnailer
  13 , fontforge
  14 , glow
  15 , imagemagick
  16 , jq
  17 , ueberzug
  18 }:
  19
  20 stdenv.mkDerivation rec {
  21   pname = "ctpv";
  22   version = "1.1";
  23
  24   src = fetchFromGitHub {
  25     owner = "NikitaIvanovV";
  26     repo = pname;
  27     rev = "v${version}";
  28     hash = "sha256-3BQi4m44hBmPkJBFNCg6d9YKRbDZwLxdzBb/NDWTQP4=";
  29   };
  30
  31   nativeBuildInputs = [ makeWrapper ];
  32
  33   buildInputs = [
  34     file # libmagic
  35     openssl
  36   ];
  37
  38   makeFlags = [ "PREFIX=$(out)" ];
  39
  40   preFixup = ''
  41     wrapProgram $out/bin/ctpv \
  42       --prefix PATH ":" "${lib.makeBinPath [
  43         atool # for archive files
  44         bat
  45         chafa # for image files on Wayland
  46         delta # for diff files
  47         ffmpeg
  48         ffmpegthumbnailer
  49         fontforge
  50         glow # for markdown files
  51         imagemagick
  52         jq # for json files
  53         ueberzug # for image files on X11
  54       ]}";
  55   '';
  56
  57   meta = with lib; {
  58     description = "File previewer for a terminal";
  59     homepage = "https://github.com/NikitaIvanovV/ctpv";
  60     license = licenses.mit;
  61     platforms = platforms.linux;
  62     maintainers = [ maintainers.wesleyjrz ];
  63   };
  64 }