pkgs/applications/office/mmex/default.nix

   1 { lib
   2 , stdenv
   3 , fetchFromGitHub
   4 , cmake
   5 , gettext
   6 , git
   7 , makeWrapper
   8 , lsb-release
   9 , pkg-config
  10 , wrapGAppsHook3
  11 , curl
  12 , sqlite
  13 , wxGTK32
  14 , gtk3
  15 , darwin
  16 }:
  17
  18 stdenv.mkDerivation rec {
  19   pname = "money-manager-ex";
  20   version = "1.6.3";
  21
  22   src = fetchFromGitHub {
  23     owner = "moneymanagerex";
  24     repo = "moneymanagerex";
  25     rev = "v${version}";
  26     fetchSubmodules = true;
  27     hash = "sha256-TQgJ2Q4Z7+OtwuwkfPBgm2BmMKML9nmyFLSkmKJ1RE4=";
  28   };
  29
  30   postPatch = lib.optionalString (stdenv.hostPlatform.isDarwin && stdenv.hostPlatform.isx86_64) ''
  31     substituteInPlace src/platfdep_mac.mm \
  32       --replace "appearance.name == NSAppearanceNameDarkAqua" "NO"
  33   '' + lib.optionalString (stdenv.hostPlatform.isLinux && !stdenv.hostPlatform.isx86_64) ''
  34     substituteInPlace 3rd/CMakeLists.txt \
  35       --replace "-msse4.2 -maes" ""
  36   '';
  37
  38   nativeBuildInputs = [
  39     cmake
  40     gettext
  41     git
  42     makeWrapper
  43     pkg-config
  44     wrapGAppsHook3
  45   ] ++ lib.optionals stdenv.hostPlatform.isLinux [
  46     lsb-release
  47   ];
  48
  49   buildInputs = [
  50     curl
  51     sqlite
  52     wxGTK32
  53     gtk3
  54   ] ++ lib.optionals stdenv.hostPlatform.isDarwin [
  55     darwin.libobjc
  56   ];
  57
  58   env.NIX_CFLAGS_COMPILE = toString (lib.optionals stdenv.cc.isClang [
  59     "-Wno-deprecated-copy"
  60     "-Wno-old-style-cast"
  61     "-Wno-unused-parameter"
  62   ]);
  63
  64   postInstall = lib.optionalString stdenv.hostPlatform.isDarwin ''
  65     mkdir -p $out/{Applications,bin}
  66     mv $out/mmex.app $out/Applications
  67     makeWrapper $out/{Applications/mmex.app/Contents/MacOS,bin}/mmex
  68   '';
  69
  70   meta = {
  71     description = "Easy-to-use personal finance software";
  72     homepage = "https://www.moneymanagerex.org/";
  73     license = lib.licenses.gpl2Plus;
  74     maintainers = [ ];
  75     platforms = with lib.platforms; unix;
  76     mainProgram = "mmex";
  77   };
  78 }