pkgs/applications/office/pdfmm/default.nix

   1 { bash
   2 , coreutils
   3 , fetchFromGitHub
   4 , ghostscript
   5 , locale
   6 , zenity
   7 , gnused
   8 , lib
   9 , resholve
  10 }:
  11
  12 resholve.mkDerivation rec {
  13   pname = "pdfmm";
  14   version = "unstable-2019-01-24";
  15
  16   src = fetchFromGitHub {
  17     owner = "jpfleury";
  18     repo = pname;
  19     rev = "45ee7796659d23bb030bf06647f1af85e1d2b52d";
  20     hash = "sha256-TOISD/2g7MwnLrtpMnfr2Ln0IiwlJVNavWl4eh/uwN0=";
  21   };
  22
  23   dontBuild = true;
  24
  25   installPhase = ''
  26     install -Dm 0755 pdfmm $out/bin/pdfmm
  27   '';
  28
  29   solutions.default = {
  30     scripts = [
  31       "bin/pdfmm"
  32     ];
  33     interpreter = "${bash}/bin/bash";
  34     inputs = [
  35       coreutils
  36       ghostscript
  37       locale
  38       zenity
  39       gnused
  40     ];
  41     fake = {
  42       # only need xmessage if zenity is unavailable
  43       external = [ "xmessage" ];
  44     };
  45     execer = [
  46       "cannot:${zenity}/bin/zenity"
  47     ];
  48     keep."$toutLu" = true;
  49   };
  50
  51   meta = with lib; {
  52     description = "Graphical assistant to reduce the size of a PDF file";
  53     homepage = "https://github.com/jpfleury/pdfmm";
  54     license = licenses.gpl3Only;
  55     maintainers = with maintainers; [ urandom ];
  56     mainProgram = "pdfmm";
  57     platforms = platforms.linux ++ platforms.darwin;
  58   };
  59 }