pkgs/tools/system/gdu/default.nix

   1 {
   2   lib,
   3   stdenv,
   4   buildGoModule,
   5   fetchFromGitHub,
   6   installShellFiles,
   7   testers,
   8   gdu,
   9 }:
  10
  11 buildGoModule rec {
  12   pname = "gdu";
  13   version = "5.29.0";
  14
  15   src = fetchFromGitHub {
  16     owner = "dundee";
  17     repo = "gdu";
  18     rev = "refs/tags/v${version}";
  19     hash = "sha256-w48I7HU/pA53Pq6ZVwtby+YvFddVUjj8orL40Gifqoo=";
  20   };
  21
  22   vendorHash = "sha256-aKhHC3sPRyi/l9BxeUgx+3TdYulb0cI9WxuPvbLoswg=";
  23
  24   nativeBuildInputs = [ installShellFiles ];
  25
  26   ldflags = [
  27     "-s"
  28     "-w"
  29     "-X=github.com/dundee/gdu/v${lib.versions.major version}/build.Version=${version}"
  30   ];
  31
  32   postPatch = ''
  33     substituteInPlace cmd/gdu/app/app_test.go \
  34       --replace-fail "development" "${version}"
  35   '';
  36
  37   postInstall = ''
  38     installManPage gdu.1
  39   '';
  40
  41   doCheck = !stdenv.hostPlatform.isDarwin;
  42
  43   checkFlags = [
  44     # https://github.com/dundee/gdu/issues/371
  45     "-skip=TestStoredAnalyzer"
  46   ];
  47
  48   passthru.tests.version = testers.testVersion { package = gdu; };
  49
  50   meta = with lib; {
  51     description = "Disk usage analyzer with console interface";
  52     longDescription = ''
  53       Gdu is intended primarily for SSD disks where it can fully
  54       utilize parallel processing. However HDDs work as well, but
  55       the performance gain is not so huge.
  56     '';
  57     homepage = "https://github.com/dundee/gdu";
  58     changelog = "https://github.com/dundee/gdu/releases/tag/v${version}";
  59     license = with licenses; [ mit ];
  60     maintainers = with maintainers; [
  61       fab
  62       zowoq
  63     ];
  64     mainProgram = "gdu";
  65   };
  66 }