pkgs/tools/networking/dd-agent/integrations-core.nix

   1 # The declarations in this file build the Datadog agent's core
   2 # integrations. These integrations are tracked in a separate
   3 # repository[1] outside of the agent's primary repository and provide
   4 # checks for various kinds of services.
   5 #
   6 # Not all services are relevant for all users, however. As some of
   7 # them depend on various tools and Python packages it is nonsensical
   8 # to build *all* integrations by default.
   9 #
  10 # A set of default integrations is defined and built either way.
  11 # Additional integrations can be specified by overriding
  12 # `extraIntegrations` in datadog-integrations-core.
  13 #
  14 # In practice the syntax for using this with additional integrations
  15 # is not the most beautiful, but it works. For example to use
  16 # datadog-agent from the top-level with the `ntp`-integration
  17 # included, one could say:
  18 #
  19 # let
  20 #   integrationsWithNtp = datadog-integrations-core {
  21 #     # Extra integrations map from the integration name (as in the
  22 #     # integrations-core repository) to a function that receives the
  23 #     # Python package set and returns the required dependencies.g
  24 #     ntp = (ps: [ ps.ntplib ]);
  25 #   };
  26 #
  27 # in ddAgentWithNtp = datadog-agent.overrideAttrs(_ : {
  28 #   python = integrationsWithNtp.python;
  29 # });
  30 #
  31 # The NixOS module 'datadog-agent' provides a simplified interface to
  32 # this. Please see the module itself for more information.
  33 #
  34 # [1]: https://github.com/DataDog/integrations-core
  35
  36 { pkgs, python, extraIntegrations ? {} }:
  37
  38 with pkgs.lib;
  39
  40 let
  41   src = pkgs.fetchFromGitHub {
  42     owner = "DataDog";
  43     repo = "integrations-core";
  44     rev = version;
  45     sha256 = "sha256-CIzuJ97KwsG1k65Y+8IUSka/3JX1pmQKN3hPHzZnGhQ=";
  46   };
  47   version = "7.38.0";
  48
  49   # Build helper to build a single datadog integration package.
  50   buildIntegration = { pname, ... }@args: python.pkgs.buildPythonPackage (args // {
  51     inherit src version;
  52     name = "datadog-integration-${pname}-${version}";
  53
  54     sourceRoot = "source/${args.sourceRoot or pname}";
  55     doCheck = false;
  56   });
  57
  58   # Base package depended on by all other integrations.
  59   datadog_checks_base = buildIntegration {
  60     pname = "checks-base";
  61     sourceRoot = "datadog_checks_base";
  62     propagatedBuildInputs = with python.pkgs; [
  63       cachetools
  64       cryptography
  65       immutables
  66       jellyfish
  67       prometheus-client
  68       protobuf
  69       pydantic
  70       python-dateutil
  71       pyyaml
  72       requests
  73       requests-toolbelt
  74       requests-unixsocket
  75       simplejson
  76       uptime
  77       wrapt
  78     ];
  79   };
  80
  81   # Default integrations that should be built:
  82   defaultIntegrations = {
  83     disk     = (ps: [ ps.psutil ]);
  84     mongo    = (ps: [ ps.pymongo ]);
  85     network  = (ps: [ ps.psutil ]);
  86     nginx    = (ps: []);
  87     postgres = (ps: with ps; [ pg8000 psycopg2 semver ]);
  88     process  = (ps: [ ps.psutil]);
  89   };
  90
  91   # All integrations (default + extra):
  92   integrations = defaultIntegrations // extraIntegrations;
  93   builtIntegrations = mapAttrs (pname: fdeps: buildIntegration {
  94     inherit pname;
  95     propagatedBuildInputs = (fdeps python.pkgs) ++ [ datadog_checks_base ];
  96   }) integrations;
  97
  98 in builtIntegrations // {
  99   inherit datadog_checks_base;
 100   python = python.withPackages (_: (attrValues builtIntegrations));
 101 }