nixos/modules/hardware/device-tree.nix

   1 { config, lib, pkgs, ... }:
   2 let
   3   cfg = config.hardware.deviceTree;
   4
   5   overlayType = lib.types.submodule {
   6     options = {
   7       name = lib.mkOption {
   8         type = lib.types.str;
   9         description = ''
  10           Name of this overlay
  11         '';
  12       };
  13
  14       filter = lib.mkOption {
  15         type = lib.types.nullOr lib.types.str;
  16         default = null;
  17         example = "*rpi*.dtb";
  18         description = ''
  19           Only apply to .dtb files matching glob expression.
  20         '';
  21       };
  22
  23       dtsFile = lib.mkOption {
  24         type = lib.types.nullOr lib.types.path;
  25         description = ''
  26           Path to .dts overlay file, overlay is applied to
  27           each .dtb file matching "compatible" of the overlay.
  28         '';
  29         default = null;
  30         example = lib.literalExpression "./dts/overlays.dts";
  31       };
  32
  33       dtsText = lib.mkOption {
  34         type = lib.types.nullOr lib.types.str;
  35         default = null;
  36         description = ''
  37           Literal DTS contents, overlay is applied to
  38           each .dtb file matching "compatible" of the overlay.
  39         '';
  40         example = ''
  41           /dts-v1/;
  42           /plugin/;
  43           / {
  44                   compatible = "raspberrypi";
  45           };
  46           &{/soc} {
  47                   pps {
  48                           compatible = "pps-gpio";
  49                           status = "okay";
  50                   };
  51           };
  52         '';
  53       };
  54
  55       dtboFile = lib.mkOption {
  56         type = lib.types.nullOr lib.types.path;
  57         default = null;
  58         description = ''
  59           Path to .dtbo compiled overlay file.
  60         '';
  61       };
  62     };
  63   };
  64
  65   filterDTBs = src: if cfg.filter == null
  66     then src
  67     else
  68       pkgs.runCommand "dtbs-filtered" {} ''
  69         mkdir -p $out
  70         cd ${src}
  71         find . -type f -name '${cfg.filter}' -print0 \
  72           | xargs -0 cp -v --no-preserve=mode --target-directory $out --parents
  73       '';
  74
  75   filteredDTBs = filterDTBs cfg.dtbSource;
  76
  77   # Fill in `dtboFile` for each overlay if not set already.
  78   # Existence of one of these is guarded by assertion below
  79   withDTBOs = xs: lib.flip map xs (o: o // { dtboFile =
  80     let
  81       includePaths = ["${lib.getDev cfg.kernelPackage}/lib/modules/${cfg.kernelPackage.modDirVersion}/source/scripts/dtc/include-prefixes"] ++ cfg.dtboBuildExtraIncludePaths;
  82       extraPreprocessorFlags = cfg.dtboBuildExtraPreprocessorFlags;
  83     in
  84     if o.dtboFile == null then
  85       let
  86         dtsFile = if o.dtsFile == null then (pkgs.writeText "dts" o.dtsText) else o.dtsFile;
  87       in
  88       pkgs.deviceTree.compileDTS {
  89         name = "${o.name}-dtbo";
  90         inherit includePaths extraPreprocessorFlags dtsFile;
  91       }
  92     else o.dtboFile; } );
  93
  94 in
  95 {
  96   imports = [
  97     (lib.mkRemovedOptionModule [ "hardware" "deviceTree" "base" ] "Use hardware.deviceTree.kernelPackage instead")
  98   ];
  99
 100   options = {
 101       hardware.deviceTree = {
 102         enable = lib.mkOption {
 103           default = pkgs.stdenv.hostPlatform.linux-kernel.DTB or false;
 104           type = lib.types.bool;
 105           description = ''
 106             Build device tree files. These are used to describe the
 107             non-discoverable hardware of a system.
 108           '';
 109         };
 110
 111         kernelPackage = lib.mkOption {
 112           default = config.boot.kernelPackages.kernel;
 113           defaultText = lib.literalExpression "config.boot.kernelPackages.kernel";
 114           example = lib.literalExpression "pkgs.linux_latest";
 115           type = lib.types.path;
 116           description = ''
 117             Kernel package where device tree include directory is from. Also used as default source of dtb package to apply overlays to
 118           '';
 119         };
 120
 121         dtboBuildExtraPreprocessorFlags = lib.mkOption {
 122           default = [];
 123           example = lib.literalExpression "[ \"-DMY_DTB_DEFINE\" ]";
 124           type = lib.types.listOf lib.types.str;
 125           description = ''
 126             Additional flags to pass to the preprocessor during dtbo compilations
 127           '';
 128         };
 129
 130         dtboBuildExtraIncludePaths = lib.mkOption {
 131           default = [];
 132           example = lib.literalExpression ''
 133             [
 134               ./my_custom_include_dir_1
 135               ./custom_include_dir_2
 136             ]
 137           '';
 138           type = lib.types.listOf lib.types.path;
 139           description = ''
 140             Additional include paths that will be passed to the preprocessor when creating the final .dts to compile into .dtbo
 141           '';
 142         };
 143
 144         dtbSource = lib.mkOption {
 145           default = "${cfg.kernelPackage}/dtbs";
 146           defaultText = lib.literalExpression "\${cfg.kernelPackage}/dtbs";
 147           type = lib.types.path;
 148           description = ''
 149             Path to dtb directory that overlays and other processing will be applied to. Uses
 150             device trees bundled with the Linux kernel by default.
 151           '';
 152         };
 153
 154         name = lib.mkOption {
 155           default = null;
 156           example = "some-dtb.dtb";
 157           type = lib.types.nullOr lib.types.str;
 158           description = ''
 159             The name of an explicit dtb to be loaded, relative to the dtb base.
 160             Useful in extlinux scenarios if the bootloader doesn't pick the
 161             right .dtb file from FDTDIR.
 162           '';
 163         };
 164
 165         filter = lib.mkOption {
 166           type = lib.types.nullOr lib.types.str;
 167           default = null;
 168           example = "*rpi*.dtb";
 169           description = ''
 170             Only include .dtb files matching glob expression.
 171           '';
 172         };
 173
 174         overlays = lib.mkOption {
 175           default = [];
 176           example = lib.literalExpression ''
 177             [
 178               { name = "pps"; dtsFile = ./dts/pps.dts; }
 179               { name = "spi";
 180                 dtsText = "...";
 181               }
 182               { name = "precompiled"; dtboFile = ./dtbos/example.dtbo; }
 183             ]
 184           '';
 185           type = lib.types.listOf (lib.types.coercedTo lib.types.path (path: {
 186             name = baseNameOf path;
 187             filter = null;
 188             dtboFile = path;
 189           }) overlayType);
 190           description = ''
 191             List of overlays to apply to base device-tree (.dtb) files.
 192           '';
 193         };
 194
 195         package = lib.mkOption {
 196           default = null;
 197           type = lib.types.nullOr lib.types.path;
 198           internal = true;
 199           description = ''
 200             A path containing the result of applying `overlays` to `kernelPackage`.
 201           '';
 202         };
 203       };
 204   };
 205
 206   config = lib.mkIf (cfg.enable) {
 207
 208     assertions = let
 209       invalidOverlay = o: (o.dtsFile == null) && (o.dtsText == null) && (o.dtboFile == null);
 210     in lib.singleton {
 211       assertion = lib.all (o: !invalidOverlay o) cfg.overlays;
 212       message = ''
 213         deviceTree overlay needs one of dtsFile, dtsText or dtboFile set.
 214         Offending overlay(s):
 215         ${toString (map (o: o.name) (builtins.filter invalidOverlay cfg.overlays))}
 216       '';
 217     };
 218
 219     hardware.deviceTree.package = if (cfg.overlays != [])
 220       then pkgs.deviceTree.applyOverlays filteredDTBs (withDTBOs cfg.overlays)
 221       else filteredDTBs;
 222   };
 223 }