nixos/modules/services/desktops/seatd.nix

   1 { config, lib, pkgs, ... }:
   2
   3 let
   4   cfg = config.services.seatd;
   5   inherit (lib) mkEnableOption mkOption types;
   6 in
   7 {
   8   meta.maintainers = with lib.maintainers; [ sinanmohd ];
   9
  10   options.services.seatd = {
  11     enable = mkEnableOption "seatd";
  12
  13     user = mkOption {
  14       type = types.str;
  15       default = "root";
  16       description = "User to own the seatd socket";
  17     };
  18     group = mkOption {
  19       type = types.str;
  20       default = "seat";
  21       description = "Group to own the seatd socket";
  22     };
  23     logLevel = mkOption {
  24       type = types.enum [ "debug" "info" "error" "silent" ];
  25       default = "info";
  26       description = "Logging verbosity";
  27     };
  28   };
  29
  30   config = lib.mkIf cfg.enable {
  31     environment.systemPackages = with pkgs; [ seatd sdnotify-wrapper ];
  32     users.groups.seat = lib.mkIf (cfg.group == "seat") {};
  33
  34     systemd.services.seatd = {
  35       description = "Seat management daemon";
  36       documentation = [ "man:seatd(1)" ];
  37
  38       wantedBy = [ "multi-user.target" ];
  39       restartIfChanged = false;
  40
  41       serviceConfig = {
  42         Type = "notify";
  43         NotifyAccess = "all";
  44         SyslogIdentifier = "seatd";
  45         ExecStart = "${pkgs.sdnotify-wrapper}/bin/sdnotify-wrapper ${pkgs.seatd.bin}/bin/seatd -n 1 -u ${cfg.user} -g ${cfg.group} -l ${cfg.logLevel}";
  46         RestartSec = 1;
  47         Restart = "always";
  48       };
  49     };
  50   };
  51 }