nixos/modules/services/hardware/brltty.nix

   1 { config, lib, pkgs, ... }:
   2 let
   3   cfg = config.services.brltty;
   4
   5   targets = [
   6     "default.target" "multi-user.target"
   7     "rescue.target" "emergency.target"
   8   ];
   9
  10   genApiKey = pkgs.writers.writeDash "generate-brlapi-key" ''
  11     if ! test -f /etc/brlapi.key; then
  12       echo -n generating brlapi key...
  13       ${pkgs.brltty}/bin/brltty-genkey -f /etc/brlapi.key
  14       echo done
  15     fi
  16   '';
  17
  18 in {
  19
  20   options = {
  21
  22     services.brltty.enable = lib.mkOption {
  23       type = lib.types.bool;
  24       default = false;
  25       description = "Whether to enable the BRLTTY daemon.";
  26     };
  27
  28   };
  29
  30   config = lib.mkIf cfg.enable {
  31     users.users.brltty = {
  32       description = "BRLTTY daemon user";
  33       group = "brltty";
  34       isSystemUser = true;
  35     };
  36     users.groups = {
  37       brltty = { };
  38       brlapi = { };
  39     };
  40
  41     systemd.services."brltty@".serviceConfig =
  42       { ExecStartPre = "!${genApiKey}"; };
  43
  44     # Install all upstream-provided files
  45     systemd.packages = [ pkgs.brltty ];
  46     systemd.tmpfiles.packages = [ pkgs.brltty ];
  47     services.udev.packages = [ pkgs.brltty ];
  48     environment.systemPackages = [ pkgs.brltty ];
  49
  50     # Add missing WantedBys (see issue #81138)
  51     systemd.paths.brltty.wantedBy = targets;
  52     systemd.paths."brltty@".wantedBy = targets;
  53   };
  54
  55 }