nixos/modules/services/hardware/fwupd.nix

   1 # fwupd daemon.
   2 { config, lib, pkgs, ... }:
   3 let
   4   cfg = config.services.fwupd;
   5
   6   format = pkgs.formats.ini {
   7     listToValue = l: lib.concatStringsSep ";" (map (s: lib.generators.mkValueStringDefault {} s) l);
   8     mkKeyValue = lib.generators.mkKeyValueDefault {} "=";
   9   };
  10
  11   customEtc = {
  12     "fwupd/fwupd.conf" = {
  13       source = format.generate "fwupd.conf" ({
  14         fwupd = cfg.daemonSettings;
  15       } // lib.optionalAttrs (lib.length (lib.attrNames cfg.uefiCapsuleSettings) != 0) {
  16         uefi_capsule = cfg.uefiCapsuleSettings;
  17       });
  18       # fwupd tries to chmod the file if it doesn't have the right permissions
  19       mode = "0640";
  20     };
  21   };
  22
  23   originalEtc =
  24     let
  25       mkEtcFile = n: lib.nameValuePair n { source = "${cfg.package}/etc/${n}"; };
  26     in lib.listToAttrs (map mkEtcFile cfg.package.filesInstalledToEtc);
  27   extraTrustedKeys =
  28     let
  29       mkName = p: "pki/fwupd/${baseNameOf (toString p)}";
  30       mkEtcFile = p: lib.nameValuePair (mkName p) { source = p; };
  31     in lib.listToAttrs (map mkEtcFile cfg.extraTrustedKeys);
  32
  33   enableRemote = base: remote: {
  34     "fwupd/remotes.d/${remote}.conf" = {
  35       source = pkgs.runCommand "${remote}-enabled.conf" {} ''
  36         sed "s,^Enabled=false,Enabled=true," \
  37         "${base}/etc/fwupd/remotes.d/${remote}.conf" > "$out"
  38       '';
  39     };
  40   };
  41   remotes = (lib.foldl'
  42     (configFiles: remote: configFiles // (enableRemote cfg.package remote))
  43     {}
  44     cfg.extraRemotes
  45   ) // (
  46     # We cannot include the file in $out and rely on filesInstalledToEtc
  47     # to install it because it would create a cyclic dependency between
  48     # the outputs. We also need to enable the remote,
  49     # which should not be done by default.
  50     lib.optionalAttrs
  51       (cfg.daemonSettings.TestDevices or false)
  52       (enableRemote cfg.package.installedTests "fwupd-tests")
  53   );
  54
  55 in {
  56
  57   ###### interface
  58   options = {
  59     services.fwupd = {
  60       enable = lib.mkOption {
  61         type = lib.types.bool;
  62         default = false;
  63         description = ''
  64           Whether to enable fwupd, a DBus service that allows
  65           applications to update firmware.
  66         '';
  67       };
  68
  69       extraTrustedKeys = lib.mkOption {
  70         type = lib.types.listOf lib.types.path;
  71         default = [];
  72         example = lib.literalExpression "[ /etc/nixos/fwupd/myfirmware.pem ]";
  73         description = ''
  74           Installing a public key allows firmware signed with a matching private key to be recognized as trusted, which may require less authentication to install than for untrusted files. By default trusted firmware can be upgraded (but not downgraded) without the user or administrator password. Only very few keys are installed by default.
  75         '';
  76       };
  77
  78       extraRemotes = lib.mkOption {
  79         type = with lib.types; listOf str;
  80         default = [];
  81         example = [ "lvfs-testing" ];
  82         description = ''
  83           Enables extra remotes in fwupd. See `/etc/fwupd/remotes.d`.
  84         '';
  85       };
  86
  87       package = lib.mkPackageOption pkgs "fwupd" { };
  88
  89       daemonSettings = lib.mkOption {
  90         type = lib.types.submodule {
  91           freeformType = format.type.nestedTypes.elemType;
  92           options = {
  93             DisabledDevices = lib.mkOption {
  94               type = lib.types.listOf lib.types.str;
  95               default = [];
  96               example = [ "2082b5e0-7a64-478a-b1b2-e3404fab6dad" ];
  97               description = ''
  98                 List of device GUIDs to be disabled.
  99               '';
 100             };
 101
 102             DisabledPlugins = lib.mkOption {
 103               type = lib.types.listOf lib.types.str;
 104               default = [];
 105               example = [ "udev" ];
 106               description = ''
 107                 List of plugins to be disabled.
 108               '';
 109             };
 110
 111             EspLocation = lib.mkOption {
 112               type = lib.types.path;
 113               default = config.boot.loader.efi.efiSysMountPoint;
 114               defaultText = lib.literalExpression "config.boot.loader.efi.efiSysMountPoint";
 115               description = ''
 116                 The EFI system partition (ESP) path used if UDisks is not available
 117                 or if this partition is not mounted at /boot/efi, /boot, or /efi
 118               '';
 119             };
 120
 121             TestDevices = lib.mkOption {
 122               internal = true;
 123               type = lib.types.bool;
 124               default = false;
 125               description = ''
 126                 Create virtual test devices and remote for validating daemon flows.
 127                 This is only intended for CI testing and development purposes.
 128               '';
 129             };
 130           };
 131         };
 132         default = {};
 133         description = ''
 134           Configurations for the fwupd daemon.
 135         '';
 136       };
 137
 138       uefiCapsuleSettings = lib.mkOption {
 139         type = lib.types.submodule {
 140           freeformType = format.type.nestedTypes.elemType;
 141         };
 142         default = {};
 143         description = ''
 144           UEFI capsule configurations for the fwupd daemon.
 145         '';
 146       };
 147     };
 148   };
 149
 150   imports = [
 151     (lib.mkRenamedOptionModule [ "services" "fwupd" "blacklistDevices"] [ "services" "fwupd" "daemonSettings" "DisabledDevices" ])
 152     (lib.mkRenamedOptionModule [ "services" "fwupd" "blacklistPlugins"] [ "services" "fwupd" "daemonSettings" "DisabledPlugins" ])
 153     (lib.mkRenamedOptionModule [ "services" "fwupd" "disabledDevices" ] [ "services" "fwupd" "daemonSettings" "DisabledDevices" ])
 154     (lib.mkRenamedOptionModule [ "services" "fwupd" "disabledPlugins" ] [ "services" "fwupd" "daemonSettings" "DisabledPlugins" ])
 155     (lib.mkRemovedOptionModule [ "services" "fwupd" "enableTestRemote" ] "This option was removed after being removed upstream. It only provided a method for testing fwupd functionality, and should not have been exposed for use outside of nix tests.")
 156   ];
 157
 158   ###### implementation
 159   config = lib.mkIf cfg.enable {
 160     # Disable test related plug-ins implicitly so that users do not have to care about them.
 161     services.fwupd.daemonSettings = {
 162       EspLocation = config.boot.loader.efi.efiSysMountPoint;
 163     };
 164
 165     environment.systemPackages = [ cfg.package ];
 166
 167     # customEtc overrides some files from the package
 168     environment.etc = originalEtc // customEtc // extraTrustedKeys // remotes;
 169
 170     services.dbus.packages = [ cfg.package ];
 171
 172     services.udev.packages = [ cfg.package ];
 173
 174     # required to update the firmware of disks
 175     services.udisks2.enable = true;
 176
 177     systemd = {
 178       packages = [ cfg.package ];
 179
 180       # fwupd-refresh expects a user that we do not create, so just run with DynamicUser
 181       # instead and ensure we take ownership of /var/lib/fwupd
 182       services.fwupd-refresh.serviceConfig = {
 183         StateDirectory = "fwupd";
 184         # Better for debugging, upstream sets stderr to null for some reason..
 185         StandardError = "inherit";
 186       };
 187
 188       timers.fwupd-refresh.wantedBy = [ "timers.target" ];
 189     };
 190
 191     users.users.fwupd-refresh = {
 192       isSystemUser = true;
 193       group = "fwupd-refresh";
 194     };
 195     users.groups.fwupd-refresh = {};
 196
 197     security.polkit.enable = true;
 198   };
 199
 200   meta = {
 201     maintainers = pkgs.fwupd.meta.maintainers;
 202   };
 203 }