nixos/modules/services/hardware/triggerhappy.nix

   1 { config, lib, pkgs, ... }:
   2 let
   3
   4   cfg = config.services.triggerhappy;
   5
   6   socket = "/run/thd.socket";
   7
   8   configFile = pkgs.writeText "triggerhappy.conf" ''
   9     ${lib.concatMapStringsSep "\n"
  10       ({ keys, event, cmd, ... }:
  11         ''${lib.concatMapStringsSep "+" (x: "KEY_" + x) keys} ${toString { press = 1; hold = 2; release = 0; }.${event}} ${cmd}''
  12       )
  13       cfg.bindings}
  14     ${cfg.extraConfig}
  15   '';
  16
  17   bindingCfg = { ... }: {
  18     options = {
  19
  20       keys = lib.mkOption {
  21         type = lib.types.listOf lib.types.str;
  22         description = "List of keys to match.  Key names as defined in linux/input-event-codes.h";
  23       };
  24
  25       event = lib.mkOption {
  26         type = lib.types.enum ["press" "hold" "release"];
  27         default = "press";
  28         description = "Event to match.";
  29       };
  30
  31       cmd = lib.mkOption {
  32         type = lib.types.str;
  33         description = "What to run.";
  34       };
  35
  36     };
  37   };
  38
  39 in
  40
  41 {
  42
  43   ###### interface
  44
  45   options = {
  46
  47     services.triggerhappy = {
  48
  49       enable = lib.mkOption {
  50         type = lib.types.bool;
  51         default = false;
  52         description = ''
  53           Whether to enable the {command}`triggerhappy` hotkey daemon.
  54         '';
  55       };
  56
  57       user = lib.mkOption {
  58         type = lib.types.str;
  59         default = "nobody";
  60         example = "root";
  61         description = ''
  62           User account under which {command}`triggerhappy` runs.
  63         '';
  64       };
  65
  66       bindings = lib.mkOption {
  67         type = lib.types.listOf (lib.types.submodule bindingCfg);
  68         default = [];
  69         example = lib.literalExpression ''
  70           [ { keys = ["PLAYPAUSE"];  cmd = "''${pkgs.mpc-cli}/bin/mpc -q toggle"; } ]
  71         '';
  72         description = ''
  73           Key bindings for {command}`triggerhappy`.
  74         '';
  75       };
  76
  77       extraConfig = lib.mkOption {
  78         type = lib.types.lines;
  79         default = "";
  80         description = ''
  81           Literal contents to append to the end of {command}`triggerhappy` configuration file.
  82         '';
  83       };
  84
  85     };
  86
  87   };
  88
  89
  90   ###### implementation
  91
  92   config = lib.mkIf cfg.enable {
  93
  94     systemd.sockets.triggerhappy = {
  95       description = "Triggerhappy Socket";
  96       wantedBy = [ "sockets.target" ];
  97       socketConfig.ListenDatagram = socket;
  98     };
  99
 100     systemd.services.triggerhappy = {
 101       wantedBy = [ "multi-user.target" ];
 102       description = "Global hotkey daemon";
 103       serviceConfig = {
 104         ExecStart = "${pkgs.triggerhappy}/bin/thd ${lib.optionalString (cfg.user != "root") "--user ${cfg.user}"} --socket ${socket} --triggers ${configFile} --deviceglob /dev/input/event*";
 105       };
 106     };
 107
 108     services.udev.packages = lib.singleton (pkgs.writeTextFile {
 109       name = "triggerhappy-udev-rules";
 110       destination = "/etc/udev/rules.d/61-triggerhappy.rules";
 111       text = ''
 112         ACTION=="add", SUBSYSTEM=="input", KERNEL=="event[0-9]*", ATTRS{name}!="triggerhappy", \
 113           RUN+="${pkgs.triggerhappy}/bin/th-cmd --socket ${socket} --passfd --udev"
 114       '';
 115     });
 116
 117   };
 118
 119 }