nixos/modules/services/logging/heartbeat.nix

   1 { config, lib, pkgs, ... }:
   2 let
   3   cfg = config.services.heartbeat;
   4
   5   heartbeatYml = pkgs.writeText "heartbeat.yml" ''
   6     name: ${cfg.name}
   7     tags: ${builtins.toJSON cfg.tags}
   8
   9     ${cfg.extraConfig}
  10   '';
  11
  12 in
  13 {
  14   options = {
  15
  16     services.heartbeat = {
  17
  18       enable = lib.mkEnableOption "heartbeat, uptime monitoring";
  19
  20       package = lib.mkPackageOption pkgs "heartbeat" {
  21         example = "heartbeat7";
  22       };
  23
  24       name = lib.mkOption {
  25         type = lib.types.str;
  26         default = "heartbeat";
  27         description = "Name of the beat";
  28       };
  29
  30       tags = lib.mkOption {
  31         type = lib.types.listOf lib.types.str;
  32         default = [];
  33         description = "Tags to place on the shipped log messages";
  34       };
  35
  36       stateDir = lib.mkOption {
  37         type = lib.types.str;
  38         default = "/var/lib/heartbeat";
  39         description = "The state directory. heartbeat's own logs and other data are stored here.";
  40       };
  41
  42       extraConfig = lib.mkOption {
  43         type = lib.types.lines;
  44         default = ''
  45           heartbeat.monitors:
  46           - type: http
  47             urls: ["http://localhost:9200"]
  48             schedule: '@every 10s'
  49         '';
  50         description = "Any other configuration options you want to add";
  51       };
  52
  53     };
  54   };
  55
  56   config = lib.mkIf cfg.enable {
  57
  58     systemd.tmpfiles.rules = [
  59       "d '${cfg.stateDir}' - nobody nogroup - -"
  60     ];
  61
  62     systemd.services.heartbeat = with pkgs; {
  63       description = "heartbeat log shipper";
  64       wantedBy = [ "multi-user.target" ];
  65       preStart = ''
  66         mkdir -p "${cfg.stateDir}"/{data,logs}
  67       '';
  68       serviceConfig = {
  69         User = "nobody";
  70         AmbientCapabilities = "cap_net_raw";
  71         ExecStart = "${cfg.package}/bin/heartbeat -c \"${heartbeatYml}\" -path.data \"${cfg.stateDir}/data\" -path.logs \"${cfg.stateDir}/logs\"";
  72       };
  73     };
  74   };
  75 }