nixos/modules/services/logging/ulogd.nix

   1 { config, lib, pkgs, ... }:
   2 let
   3   cfg = config.services.ulogd;
   4   settingsFormat = pkgs.formats.ini { listsAsDuplicateKeys = true; };
   5   settingsFile = settingsFormat.generate "ulogd.conf" cfg.settings;
   6 in {
   7   options = {
   8     services.ulogd = {
   9       enable = lib.mkEnableOption "ulogd, a userspace logging daemon for netfilter/iptables related logging";
  10
  11       settings = lib.mkOption {
  12         example = {
  13           global.stack = [
  14             "log1:NFLOG,base1:BASE,ifi1:IFINDEX,ip2str1:IP2STR,print1:PRINTPKT,emu1:LOGEMU"
  15             "log1:NFLOG,base1:BASE,pcap1:PCAP"
  16           ];
  17
  18           log1.group = 2;
  19
  20           pcap1 = {
  21             sync = 1;
  22             file = "/var/log/ulogd.pcap";
  23           };
  24
  25           emu1 = {
  26             sync = 1;
  27             file = "/var/log/ulogd_pkts.log";
  28           };
  29         };
  30         type = settingsFormat.type;
  31         default = { };
  32         description =
  33           "Configuration for ulogd. See {file}`/share/doc/ulogd/` in `pkgs.ulogd.doc`.";
  34       };
  35
  36       logLevel = lib.mkOption {
  37         type = lib.types.enum [ 1 3 5 7 8 ];
  38         default = 5;
  39         description =
  40           "Log level (1 = debug, 3 = info, 5 = notice, 7 = error, 8 = fatal)";
  41       };
  42     };
  43   };
  44
  45   config = lib.mkIf cfg.enable {
  46     systemd.services.ulogd = {
  47       description = "Ulogd Daemon";
  48       wantedBy = [ "multi-user.target" ];
  49       wants = [ "network-pre.target" ];
  50       before = [ "network-pre.target" ];
  51
  52       serviceConfig = {
  53         ExecStart =
  54           "${pkgs.ulogd}/bin/ulogd -c ${settingsFile} --verbose --loglevel ${
  55             toString cfg.logLevel
  56           }";
  57         ExecReload = "${pkgs.coreutils}/bin/kill -HUP $MAINPID";
  58       };
  59     };
  60   };
  61 }