nixos/modules/services/misc/bcg.nix

   1 {
   2   config,
   3   lib,
   4   pkgs,
   5   ...
   6 }:
   7 let
   8   cfg = config.services.bcg;
   9   configFile = (pkgs.formats.yaml {}).generate "bcg.conf.yaml" (
  10     lib.filterAttrsRecursive (n: v: v != null) {
  11       inherit (cfg) device name mqtt;
  12       retain_node_messages = cfg.retainNodeMessages;
  13       qos_node_messages = cfg.qosNodeMessages;
  14       base_topic_prefix = cfg.baseTopicPrefix;
  15       automatic_remove_kit_from_names = cfg.automaticRemoveKitFromNames;
  16       automatic_rename_kit_nodes = cfg.automaticRenameKitNodes;
  17       automatic_rename_generic_nodes = cfg.automaticRenameGenericNodes;
  18       automatic_rename_nodes = cfg.automaticRenameNodes;
  19     }
  20   );
  21 in
  22 {
  23   options = {
  24     services.bcg = {
  25       enable = lib.mkEnableOption "BigClown gateway";
  26       package = lib.mkPackageOption pkgs [ "python3Packages" "bcg" ] { };
  27       environmentFiles = lib.mkOption {
  28         type = lib.types.listOf lib.types.path;
  29         default = [];
  30         example = [ "/run/keys/bcg.env" ];
  31         description = ''
  32           File to load as environment file. Environment variables from this file
  33           will be interpolated into the config file using envsubst with this
  34           syntax: `$ENVIRONMENT` or `''${VARIABLE}`.
  35           This is useful to avoid putting secrets into the nix store.
  36         '';
  37       };
  38       verbose = lib.mkOption {
  39         type = lib.types.enum ["CRITICAL" "ERROR" "WARNING" "INFO" "DEBUG"];
  40         default = "WARNING";
  41         description = "Verbosity level.";
  42       };
  43       device = lib.mkOption {
  44         type = lib.types.str;
  45         description = "Device name to configure gateway to use.";
  46       };
  47       name = lib.mkOption {
  48         type = with lib.types; nullOr str;
  49         default = null;
  50         description = ''
  51           Name for the device.
  52
  53           Supported variables:
  54           * `{ip}` IP address
  55           * `{id}` The ID of the connected usb-dongle or core-module
  56
  57           `null` can be used for automatic detection from gateway firmware.
  58         '';
  59       };
  60       mqtt = {
  61         host = lib.mkOption {
  62           type = lib.types.str;
  63           default = "127.0.0.1";
  64           description = "Host where MQTT server is running.";
  65         };
  66         port = lib.mkOption {
  67           type = lib.types.port;
  68           default = 1883;
  69           description = "Port of MQTT server.";
  70         };
  71         username = lib.mkOption {
  72           type = with lib.types; nullOr str;
  73           default = null;
  74           description = "MQTT server access username.";
  75         };
  76         password = lib.mkOption {
  77           type = with lib.types; nullOr str;
  78           default = null;
  79           description = "MQTT server access password.";
  80         };
  81         cafile = lib.mkOption {
  82           type = with lib.types; nullOr str;
  83           default = null;
  84           description = "Certificate Authority file for MQTT server access.";
  85         };
  86         certfile = lib.mkOption {
  87           type = with lib.types; nullOr str;
  88           default = null;
  89           description = "Certificate file for MQTT server access.";
  90         };
  91         keyfile = lib.mkOption {
  92           type = with lib.types; nullOr str;
  93           default = null;
  94           description = "Key file for MQTT server access.";
  95         };
  96       };
  97       retainNodeMessages = lib.mkOption {
  98         type = lib.types.bool;
  99         default = false;
 100         description = "Specify that node messages should be retaied in MQTT broker.";
 101       };
 102       qosNodeMessages = lib.mkOption {
 103         type = lib.types.int;
 104         default = 1;
 105         description = "Set the guarantee of MQTT message delivery.";
 106       };
 107       baseTopicPrefix = lib.mkOption {
 108         type = lib.types.str;
 109         default = "";
 110         description = "Topic prefix added to all MQTT messages.";
 111       };
 112       automaticRemoveKitFromNames = lib.mkOption {
 113         type = lib.types.bool;
 114         default = true;
 115         description = "Automatically remove kits.";
 116       };
 117       automaticRenameKitNodes = lib.mkOption {
 118         type = lib.types.bool;
 119         default = true;
 120         description = "Automatically rename kit's nodes.";
 121       };
 122       automaticRenameGenericNodes = lib.mkOption {
 123         type = lib.types.bool;
 124         default = true;
 125         description = "Automatically rename generic nodes.";
 126       };
 127       automaticRenameNodes = lib.mkOption {
 128         type = lib.types.bool;
 129         default = true;
 130         description = "Automatically rename all nodes.";
 131       };
 132       rename = lib.mkOption {
 133         type = with lib.types; attrsOf str;
 134         default = {};
 135         description = "Rename nodes to different name.";
 136       };
 137     };
 138   };
 139
 140   config = lib.mkIf cfg.enable {
 141     environment.systemPackages = with pkgs; [
 142       python3Packages.bcg
 143       python3Packages.bch
 144     ];
 145
 146     systemd.services.bcg = let
 147       envConfig = cfg.environmentFiles != [];
 148       finalConfig = if envConfig
 149                     then "\${RUNTIME_DIRECTORY}/bcg.config.yaml"
 150                     else configFile;
 151     in {
 152       description = "BigClown Gateway";
 153       wantedBy = [ "multi-user.target" ];
 154       wants = [ "network-online.target" ] ++ lib.optional config.services.mosquitto.enable "mosquitto.service";
 155       after = [ "network-online.target" ];
 156       preStart = lib.mkIf envConfig ''
 157         umask 077
 158         ${pkgs.envsubst}/bin/envsubst -i "${configFile}" -o "${finalConfig}"
 159         '';
 160       serviceConfig = {
 161         EnvironmentFile = cfg.environmentFiles;
 162         ExecStart = "${cfg.package}/bin/bcg -c ${finalConfig} -v ${cfg.verbose}";
 163         RuntimeDirectory = "bcg";
 164       };
 165     };
 166   };
 167 }