nixos/modules/services/misc/calibre-server.nix

   1 { config, lib, pkgs, ... }:
   2 let
   3
   4   cfg = config.services.calibre-server;
   5
   6   documentationLink = "https://manual.calibre-ebook.com";
   7   generatedDocumentationLink = documentationLink + "/generated/en/calibre-server.html";
   8
   9   execFlags = (lib.concatStringsSep " "
  10     (lib.mapAttrsToList (k: v: "${k} ${toString v}") (lib.filterAttrs (name: value: value != null) {
  11       "--listen-on" = cfg.host;
  12       "--port" = cfg.port;
  13       "--auth-mode" = cfg.auth.mode;
  14       "--userdb" = cfg.auth.userDb;
  15     }) ++ [(lib.optionalString (cfg.auth.enable == true) "--enable-auth")])
  16   );
  17 in
  18
  19 {
  20   imports = [
  21     (lib.mkChangedOptionModule [ "services" "calibre-server" "libraryDir" ] [ "services" "calibre-server" "libraries" ]
  22       (config:
  23         let libraryDir = lib.getAttrFromPath [ "services" "calibre-server" "libraryDir" ] config;
  24         in [ libraryDir ]
  25       )
  26     )
  27   ];
  28
  29   options = {
  30     services.calibre-server = {
  31
  32       enable = lib.mkEnableOption "calibre-server (e-book software)";
  33       package = lib.mkPackageOption pkgs "calibre" { };
  34
  35       libraries = lib.mkOption {
  36         type = lib.types.listOf lib.types.path;
  37         default = [ "/var/lib/calibre-server" ];
  38         description = ''
  39           Make sure each library path is initialized before service startup.
  40           The directories of the libraries to serve. They must be readable for the user under which the server runs.
  41           See the [calibredb documentation](${documentationLink}/generated/en/calibredb.html#add) for details.
  42         '';
  43       };
  44
  45       user = lib.mkOption {
  46         type = lib.types.str;
  47         default = "calibre-server";
  48         description = "The user under which calibre-server runs.";
  49       };
  50
  51       group = lib.mkOption {
  52         type = lib.types.str;
  53         default = "calibre-server";
  54         description = "The group under which calibre-server runs.";
  55       };
  56
  57       host = lib.mkOption {
  58         type = lib.types.str;
  59         default = "0.0.0.0";
  60         example = "::1";
  61         description = ''
  62           The interface on which to listen for connections.
  63           See the [calibre-server documentation](${generatedDocumentationLink}#cmdoption-calibre-server-listen-on) for details.
  64         '';
  65       };
  66
  67       port = lib.mkOption {
  68         default = 8080;
  69         type = lib.types.port;
  70         description = ''
  71           The port on which to listen for connections.
  72           See the [calibre-server documentation](${generatedDocumentationLink}#cmdoption-calibre-server-port) for details.
  73         '';
  74       };
  75
  76       auth = {
  77         enable = lib.mkOption {
  78           type = lib.types.bool;
  79           default = false;
  80           description = ''
  81             Password based authentication to access the server.
  82             See the [calibre-server documentation](${generatedDocumentationLink}#cmdoption-calibre-server-enable-auth) for details.
  83           '';
  84         };
  85
  86         mode = lib.mkOption {
  87           type = lib.types.enum [ "auto" "basic" "digest" ];
  88           default = "auto";
  89           description = ''
  90             Choose the type of authentication used.
  91             Set the HTTP authentication mode used by the server.
  92             See the [calibre-server documentation](${generatedDocumentationLink}#cmdoption-calibre-server-auth-mode) for details.
  93           '';
  94         };
  95
  96         userDb = lib.mkOption {
  97           default = null;
  98           type = lib.types.nullOr lib.types.path;
  99           description = ''
 100             Choose users database file to use for authentication.
 101             Make sure users database file is initialized before service startup.
 102             See the [calibre-server documentation](${documentationLink}/server.html#managing-user-accounts-from-the-command-line-only) for details.
 103           '';
 104         };
 105       };
 106     };
 107   };
 108
 109   config = lib.mkIf cfg.enable {
 110
 111     systemd.services.calibre-server = {
 112       description = "Calibre Server";
 113       after = [ "network.target" ];
 114       wantedBy = [ "multi-user.target" ];
 115       serviceConfig = {
 116         User = cfg.user;
 117         Restart = "always";
 118         ExecStart = "${cfg.package}/bin/calibre-server ${lib.concatStringsSep " " cfg.libraries} ${execFlags}";
 119       };
 120
 121     };
 122
 123     environment.systemPackages = [ pkgs.calibre ];
 124
 125     users.users = lib.optionalAttrs (cfg.user == "calibre-server") {
 126       calibre-server = {
 127         home = "/var/lib/calibre-server";
 128         createHome = true;
 129         uid = config.ids.uids.calibre-server;
 130         group = cfg.group;
 131       };
 132     };
 133
 134     users.groups = lib.optionalAttrs (cfg.group == "calibre-server") {
 135       calibre-server = {
 136         gid = config.ids.gids.calibre-server;
 137       };
 138     };
 139
 140   };
 141
 142   meta.maintainers = with lib.maintainers; [ gaelreyrol ];
 143 }