nixos/modules/services/misc/owncast.nix

   1 { lib, pkgs, config, ... }:
   2 let cfg = config.services.owncast;
   3 in {
   4
   5   options.services.owncast = {
   6
   7     enable = lib.mkEnableOption "owncast, a video live streaming solution";
   8
   9     dataDir = lib.mkOption {
  10       type = lib.types.str;
  11       default = "/var/lib/owncast";
  12       description = ''
  13         The directory where owncast stores its data files. If left as the default value this directory will automatically be created before the owncast server starts, otherwise the sysadmin is responsible for ensuring the directory exists with appropriate ownership and permissions.
  14       '';
  15     };
  16
  17     openFirewall = lib.mkOption {
  18       type = lib.types.bool;
  19       default = false;
  20       description = ''
  21         Open the appropriate ports in the firewall for owncast.
  22       '';
  23     };
  24
  25     user = lib.mkOption {
  26       type = lib.types.str;
  27       default = "owncast";
  28       description = "User account under which owncast runs.";
  29     };
  30
  31     group = lib.mkOption {
  32       type = lib.types.str;
  33       default = "owncast";
  34       description = "Group under which owncast runs.";
  35     };
  36
  37     listen = lib.mkOption {
  38       type = lib.types.str;
  39       default = "127.0.0.1";
  40       example = "0.0.0.0";
  41       description = "The IP address to bind the owncast web server to.";
  42     };
  43
  44     port = lib.mkOption {
  45       type = lib.types.port;
  46       default = 8080;
  47       description = ''
  48         TCP port where owncast web-gui listens.
  49       '';
  50     };
  51
  52     rtmp-port = lib.mkOption {
  53       type = lib.types.port;
  54       default = 1935;
  55       description = ''
  56         TCP port where owncast rtmp service listens.
  57       '';
  58     };
  59
  60   };
  61
  62   config = lib.mkIf cfg.enable {
  63
  64     systemd.services.owncast = {
  65       description = "A self-hosted live video and web chat server";
  66       wantedBy = [ "multi-user.target" ];
  67
  68       serviceConfig = lib.mkMerge [
  69         {
  70           User = cfg.user;
  71           Group = cfg.group;
  72           WorkingDirectory = cfg.dataDir;
  73           ExecStart = "${pkgs.owncast}/bin/owncast -webserverport ${toString cfg.port} -rtmpport ${toString cfg.rtmp-port} -webserverip ${cfg.listen}";
  74           Restart = "on-failure";
  75         }
  76         (lib.mkIf (cfg.dataDir == "/var/lib/owncast") {
  77           StateDirectory = "owncast";
  78         })
  79       ];
  80     };
  81
  82     users.users = lib.mkIf (cfg.user == "owncast") {
  83       owncast = {
  84         isSystemUser = true;
  85         group = cfg.group;
  86         description = "owncast system user";
  87       };
  88     };
  89
  90     users.groups = lib.mkIf (cfg.group == "owncast") { owncast = { }; };
  91
  92     networking.firewall =
  93       lib.mkIf cfg.openFirewall { allowedTCPPorts = [ cfg.rtmp-port ] ++ lib.optional (cfg.listen != "127.0.0.1") cfg.port; };
  94
  95   };
  96   meta = { maintainers = with lib.maintainers; [ MayNiklas ]; };
  97 }