nixos/modules/services/misc/pinnwand.nix

   1 { config, lib, pkgs, ... }:
   2
   3 with lib;
   4
   5 let
   6   cfg = config.services.pinnwand;
   7
   8   format = pkgs.formats.toml {};
   9   configFile = format.generate "pinnwand.toml" cfg.settings;
  10 in
  11 {
  12   options.services.pinnwand = {
  13     enable = mkEnableOption "Pinnwand, a pastebin";
  14
  15     port = mkOption {
  16       type = types.port;
  17       description = "The port to listen on.";
  18       default = 8000;
  19     };
  20
  21     settings = mkOption {
  22       default = {};
  23       description = ''
  24         Your {file}`pinnwand.toml` as a Nix attribute set. Look up
  25         possible options in the [documentation](https://pinnwand.readthedocs.io/en/v${pkgs.pinnwand.version}/configuration.html).
  26       '';
  27       type = types.submodule {
  28         freeformType = format.type;
  29         options = {
  30           database_uri = mkOption {
  31             type = types.str;
  32             default = "sqlite:////var/lib/pinnwand/pinnwand.db";
  33             example = "sqlite:///:memory";
  34             description = ''
  35               Database URI compatible with [SQLAlchemyhttps://docs.sqlalchemy.org/en/14/core/engines.html#database-urls].
  36
  37               Additional packages may need to be introduced into the environment for certain databases.
  38             '';
  39           };
  40
  41           paste_size = mkOption {
  42             type = types.ints.positive;
  43             default = 262144;
  44             example = 524288;
  45             description = ''
  46               Maximum size of a paste in bytes.
  47             '';
  48           };
  49           paste_help = mkOption {
  50             type = types.str;
  51             default = ''
  52               <p>Welcome to pinnwand, this site is a pastebin. It allows you to share code with others. If you write code in the text area below and press the paste button you will be given a link you can share with others so they can view your code as well.</p><p>People with the link can view your pasted code, only you can remove your paste and it expires automatically. Note that anyone could guess the URI to your paste so don't rely on it being private.</p>
  53               '';
  54             description = ''
  55               Raw HTML help text shown in the header area.
  56             '';
  57           };
  58           footer = mkOption {
  59             type = types.str;
  60             default = ''
  61               View <a href="//github.com/supakeen/pinnwand" target="_BLANK">source code</a>, the <a href="/removal">removal</a> or <a href="/expiry">expiry</a> stories, or read the <a href="/about">about</a> page.
  62             '';
  63             description = ''
  64               The footer in raw HTML.
  65             '';
  66           };
  67         };
  68       };
  69     };
  70   };
  71
  72   config = mkIf cfg.enable {
  73     systemd.services.pinnwand = {
  74       description = "Pinnwannd HTTP Server";
  75       after = [ "network.target" ];
  76       wantedBy = [ "multi-user.target" ];
  77
  78       unitConfig.Documentation = "https://pinnwand.readthedocs.io/en/latest/";
  79
  80       serviceConfig = {
  81         ExecStart = "${pkgs.pinnwand}/bin/pinnwand --configuration-path ${configFile} http --port ${toString cfg.port}";
  82         User = "pinnwand";
  83         DynamicUser = true;
  84
  85         StateDirectory = "pinnwand";
  86         StateDirectoryMode = "0700";
  87
  88         AmbientCapabilities = [];
  89         CapabilityBoundingSet = "";
  90         DevicePolicy = "closed";
  91         LockPersonality = true;
  92         MemoryDenyWriteExecute = true;
  93         PrivateDevices = true;
  94         PrivateUsers = true;
  95         ProcSubset = "pid";
  96         ProtectClock = true;
  97         ProtectControlGroups = true;
  98         ProtectHome = true;
  99         ProtectHostname = true;
 100         ProtectKernelLogs = true;
 101         ProtectKernelModules = true;
 102         ProtectKernelTunables = true;
 103         ProtectProc = "invisible";
 104         RestrictAddressFamilies = [
 105           "AF_UNIX"
 106           "AF_INET"
 107           "AF_INET6"
 108         ];
 109         RestrictNamespaces = true;
 110         RestrictRealtime = true;
 111         SystemCallArchitectures = "native";
 112         SystemCallFilter = [
 113           "@system-service"
 114           "~@privileged"
 115         ];
 116         UMask = "0077";
 117       };
 118     };
 119   };
 120
 121   meta.buildDocsInSandbox = false;
 122 }