nixos/modules/services/network-filesystems/rsyncd.nix

   1 { config, pkgs, lib, ... }:
   2 let
   3   cfg = config.services.rsyncd;
   4   settingsFormat = pkgs.formats.ini { };
   5   configFile = settingsFormat.generate "rsyncd.conf" cfg.settings;
   6 in {
   7   options = {
   8     services.rsyncd = {
   9
  10       enable = lib.mkEnableOption "the rsync daemon";
  11
  12       port = lib.mkOption {
  13         default = 873;
  14         type = lib.types.port;
  15         description = "TCP port the daemon will listen on.";
  16       };
  17
  18       settings = lib.mkOption {
  19         inherit (settingsFormat) type;
  20         default = { };
  21         example = {
  22           global = {
  23             uid = "nobody";
  24             gid = "nobody";
  25             "use chroot" = true;
  26             "max connections" = 4;
  27           };
  28           ftp = {
  29             path = "/var/ftp/./pub";
  30             comment = "whole ftp area";
  31           };
  32           cvs = {
  33             path = "/data/cvs";
  34             comment = "CVS repository (requires authentication)";
  35             "auth users" = [ "tridge" "susan" ];
  36             "secrets file" = "/etc/rsyncd.secrets";
  37           };
  38         };
  39         description = ''
  40           Configuration for rsyncd. See
  41           {manpage}`rsyncd.conf(5)`.
  42         '';
  43       };
  44
  45       socketActivated = lib.mkOption {
  46         default = false;
  47         type = lib.types.bool;
  48         description = "If enabled Rsync will be socket-activated rather than run persistently.";
  49       };
  50
  51     };
  52   };
  53
  54   imports = (map (option:
  55     lib.mkRemovedOptionModule [ "services" "rsyncd" option ]
  56     "This option was removed in favor of `services.rsyncd.settings`.") [
  57       "address"
  58       "extraConfig"
  59       "motd"
  60       "user"
  61       "group"
  62     ]);
  63
  64   config = lib.mkIf cfg.enable {
  65
  66     services.rsyncd.settings.global.port = toString cfg.port;
  67
  68     systemd = let
  69       serviceConfigSecurity = {
  70         ProtectSystem = "full";
  71         PrivateDevices = "on";
  72         NoNewPrivileges = "on";
  73       };
  74     in {
  75       services.rsync = {
  76         enable = !cfg.socketActivated;
  77         aliases = [ "rsyncd.service" ];
  78
  79         description = "fast remote file copy program daemon";
  80         after = [ "network.target" ];
  81         documentation = [ "man:rsync(1)" "man:rsyncd.conf(5)" ];
  82
  83         serviceConfig = serviceConfigSecurity // {
  84           ExecStart =
  85             "${pkgs.rsync}/bin/rsync --daemon --no-detach --config=${configFile}";
  86           RestartSec = 1;
  87         };
  88
  89         wantedBy = [ "multi-user.target" ];
  90       };
  91
  92       services."rsync@" = {
  93         description = "fast remote file copy program daemon";
  94         after = [ "network.target" ];
  95
  96         serviceConfig = serviceConfigSecurity // {
  97           ExecStart = "${pkgs.rsync}/bin/rsync --daemon --config=${configFile}";
  98           StandardInput = "socket";
  99           StandardOutput = "inherit";
 100           StandardError = "journal";
 101         };
 102       };
 103
 104       sockets.rsync = {
 105         enable = cfg.socketActivated;
 106
 107         description = "socket for fast remote file copy program daemon";
 108         conflicts = [ "rsync.service" ];
 109
 110         listenStreams = [ (toString cfg.port) ];
 111         socketConfig.Accept = true;
 112
 113         wantedBy = [ "sockets.target" ];
 114       };
 115     };
 116
 117   };
 118
 119   meta.maintainers = with lib.maintainers; [ ehmry ];
 120
 121   # TODO: socket activated rsyncd
 122
 123 }