nixos/modules/services/web-apps/node-red.nix

   1 { config, lib, pkgs, ... }:
   2
   3 with lib;
   4
   5 let
   6   cfg = config.services.node-red;
   7   defaultUser = "node-red";
   8 in
   9 {
  10   options.services.node-red = {
  11     enable = mkEnableOption "the Node-RED service";
  12
  13     package = mkPackageOption pkgs [ "nodePackages" "node-red" ] { };
  14
  15     openFirewall = mkOption {
  16       type = types.bool;
  17       default = false;
  18       description = ''
  19         Open ports in the firewall for the server.
  20       '';
  21     };
  22
  23     withNpmAndGcc = mkOption {
  24       type = types.bool;
  25       default = false;
  26       description = ''
  27         Give Node-RED access to NPM and GCC at runtime, so 'Nodes' can be
  28         downloaded and managed imperatively via the 'Palette Manager'.
  29       '';
  30     };
  31
  32     configFile = mkOption {
  33       type = types.path;
  34       default = "${cfg.package}/lib/node_modules/node-red/settings.js";
  35       defaultText = literalExpression ''"''${package}/lib/node_modules/node-red/settings.js"'';
  36       description = ''
  37         Path to the JavaScript configuration file.
  38         See <https://github.com/node-red/node-red/blob/master/packages/node_modules/node-red/settings.js>
  39         for a configuration example.
  40       '';
  41     };
  42
  43     port = mkOption {
  44       type = types.port;
  45       default = 1880;
  46       description = "Listening port.";
  47     };
  48
  49     user = mkOption {
  50       type = types.str;
  51       default = defaultUser;
  52       description = ''
  53         User under which Node-RED runs.If left as the default value this user
  54         will automatically be created on system activation, otherwise the
  55         sysadmin is responsible for ensuring the user exists.
  56       '';
  57     };
  58
  59     group = mkOption {
  60       type = types.str;
  61       default = defaultUser;
  62       description = ''
  63         Group under which Node-RED runs.If left as the default value this group
  64         will automatically be created on system activation, otherwise the
  65         sysadmin is responsible for ensuring the group exists.
  66       '';
  67     };
  68
  69     userDir = mkOption {
  70       type = types.path;
  71       default = "/var/lib/node-red";
  72       description = ''
  73         The directory to store all user data, such as flow and credential files and all library data. If left
  74         as the default value this directory will automatically be created before the node-red service starts,
  75         otherwise the sysadmin is responsible for ensuring the directory exists with appropriate ownership
  76         and permissions.
  77       '';
  78     };
  79
  80     safe = mkOption {
  81       type = types.bool;
  82       default = false;
  83       description = "Whether to launch Node-RED in --safe mode.";
  84     };
  85
  86     define = mkOption {
  87       type = types.attrs;
  88       default = {};
  89       description = "List of settings.js overrides to pass via -D to Node-RED.";
  90       example = literalExpression ''
  91         {
  92           "logging.console.level" = "trace";
  93         }
  94       '';
  95     };
  96   };
  97
  98   config = mkIf cfg.enable {
  99     users.users = optionalAttrs (cfg.user == defaultUser) {
 100       ${defaultUser} = {
 101         isSystemUser = true;
 102         group = defaultUser;
 103       };
 104     };
 105
 106     users.groups = optionalAttrs (cfg.group == defaultUser) {
 107       ${defaultUser} = { };
 108     };
 109
 110     networking.firewall = mkIf cfg.openFirewall {
 111       allowedTCPPorts = [ cfg.port ];
 112     };
 113
 114     systemd.services.node-red = {
 115       description = "Node-RED Service";
 116       wantedBy = [ "multi-user.target" ];
 117       after = [ "networking.target" ];
 118       environment = {
 119         HOME = cfg.userDir;
 120       };
 121       path = lib.optionals cfg.withNpmAndGcc [ pkgs.nodePackages.npm pkgs.gcc ];
 122       serviceConfig = mkMerge [
 123         {
 124           User = cfg.user;
 125           Group = cfg.group;
 126           ExecStart = "${cfg.package}/bin/node-red ${pkgs.lib.optionalString cfg.safe "--safe"} --settings ${cfg.configFile} --port ${toString cfg.port} --userDir ${cfg.userDir} ${concatStringsSep " " (mapAttrsToList (name: value: "-D ${name}=${value}") cfg.define)}";
 127           PrivateTmp = true;
 128           Restart = "always";
 129           WorkingDirectory = cfg.userDir;
 130         }
 131         (mkIf (cfg.userDir == "/var/lib/node-red") { StateDirectory = "node-red"; })
 132       ];
 133     };
 134   };
 135 }