pkgs/applications/window-managers/yabar/build.nix

   1 { stdenv, fetchFromGitHub, cairo, gdk-pixbuf, libconfig, pango, pkg-config
   2 , xcbutilwm, alsa-lib, wirelesstools, asciidoc, libxslt, makeWrapper, docbook_xsl
   3 , configFile ? null, lib
   4 , rev, sha256, version, patches ? []
   5 }:
   6
   7 stdenv.mkDerivation {
   8   pname = "yabar";
   9   inherit version;
  10
  11   src = fetchFromGitHub {
  12     inherit rev sha256;
  13
  14     owner = "geommer";
  15     repo  = "yabar";
  16   };
  17
  18   inherit patches;
  19
  20   hardeningDisable = [ "format" ];
  21
  22   strictDeps = true;
  23   depsBuildBuild = [
  24     pkg-config
  25   ];
  26   nativeBuildInputs = [
  27     pkg-config
  28     asciidoc
  29     docbook_xsl
  30     libxslt
  31     makeWrapper
  32     libconfig
  33     pango
  34   ];
  35   buildInputs = [
  36     cairo
  37     gdk-pixbuf
  38     libconfig
  39     pango
  40     xcbutilwm
  41     alsa-lib
  42     wirelesstools
  43   ];
  44
  45   postPatch = ''
  46     substituteInPlace ./Makefile \
  47       --replace "\$(shell git describe)" "${version}" \
  48       --replace "a2x" "a2x --no-xmllint"
  49   '';
  50
  51   makeFlags = [ "DESTDIR=$(out)" "PREFIX=/" ];
  52
  53   postInstall = ''
  54     mkdir -p $out/share/yabar/examples
  55     cp -v examples/*.config $out/share/yabar/examples
  56
  57     ${lib.optionalString (configFile != null)
  58       ''
  59         wrapProgram "$out/bin/yabar" \
  60           --add-flags "-c ${configFile}"
  61       ''
  62     }
  63   '';
  64
  65   meta = with lib; {
  66     description = "A modern and lightweight status bar for X window managers";
  67     homepage    = "https://github.com/geommer/yabar";
  68     license     = licenses.mit;
  69     platforms   = platforms.linux;
  70     maintainers = with maintainers; [ ];
  71     mainProgram = "yabar";
  72   };
  73 }