pkgs/tools/networking/djbdns/default.nix

   1 { lib, stdenv, fetchurl, glibc, dns-root-data, nixosTests } :
   2
   3 let
   4   version = "1.05";
   5
   6   manSrc = fetchurl {
   7     url = "http://smarden.org/pape/djb/manpages/djbdns-${version}-man-20031023.tar.gz";
   8     sha256 = "0sg51gjy6j1hnrra406q1qhf5kvk1m00y8qqhs6r0a699gqmh75s";
   9   };
  10
  11 in
  12
  13 stdenv.mkDerivation {
  14   pname = "djbdns";
  15   inherit version;
  16
  17   src = fetchurl {
  18     url = "https://cr.yp.to/djbdns/djbdns-${version}.tar.gz";
  19     sha256 = "0j3baf92vkczr5fxww7rp1b7gmczxmmgrqc8w2dy7kgk09m85k9w";
  20   };
  21
  22   patches = [
  23     ./hier.patch
  24     ./fix-nix-usernamespace-build.patch
  25
  26     # To fix https://github.com/NixOS/nixpkgs/issues/119066.
  27     # Note that the NixOS test <nixpkgs/nixos/tests/tinydns.nix> tests for this.
  28     ./softlimit.patch
  29   ];
  30
  31   postPatch = ''
  32     echo gcc -O2 -include ${glibc.dev}/include/errno.h > conf-cc
  33     echo $out > conf-home
  34     # djbdns ships with an outdated list of root servers
  35     awk '/^.?.ROOT-SERVERS.NET/ { print $4 }' ${dns-root-data}/root.hints > dnsroots.global
  36     sed -i "s|/etc/dnsroots.global|$out/etc/dnsroots.global|" dnscache-conf.c
  37   '';
  38
  39   installPhase = ''
  40     mkdir -pv $out/etc;
  41     make setup
  42     cd $out;
  43     tar xzvf ${manSrc};
  44     for n in 1 5 8; do
  45       mkdir -p man/man$n;
  46       mv -iv djbdns-man/*.$n man/man$n;
  47     done;
  48     rm -rv djbdns-man;
  49   '';
  50
  51   passthru.tests = {
  52     tinydns = nixosTests.tinydns;
  53   };
  54
  55   meta = with lib; {
  56     description = "A collection of Domain Name System tools";
  57     longDescription = "Includes software for all the fundamental DNS operations: DNS cache: finding addresses of Internet hosts; DNS server: publishing addresses of Internet hosts; and DNS client: talking to a DNS cache.";
  58     homepage = "https://cr.yp.to/djbdns.html";
  59     license = licenses.publicDomain;
  60     maintainers = with maintainers; [ jerith666 ];
  61   };
  62 }