pkgs/tools/networking/nettee/default.nix

   1 { stdenv, lib, fetchurl, cleanPackaging }:
   2
   3 let
   4   version = "0.3.4";
   5   sha256 = "00xbkp99x9v07r34w7m2p8gak5hdsdbka36n7a733rdrrkgf5z7r";
   6
   7 in stdenv.mkDerivation {
   8   pname = "nettee";
   9   inherit version;
  10
  11   src = fetchurl {
  12     url = "http://saf.bio.caltech.edu/pub/software/linux_or_unix_tools/beta-nettee-${version}.tar.gz";
  13     inherit sha256;
  14   };
  15
  16   meta = {
  17     homepage = "http://saf.bio.caltech.edu/nettee.html";
  18     description = ''Network "tee" program'';
  19     license = lib.licenses.gpl2Only;
  20     maintainers = with lib.maintainers; [ Profpatsch ];
  21     platforms = lib.platforms.linux;
  22     mainProgram = "nettee";
  23   };
  24
  25   outputs = [ "bin" "man" "doc" "out" ];
  26
  27   patchPhase = ''
  28     # h_addr field was removed
  29     sed -e '1 i #define h_addr h_addr_list[0]' \
  30         -i nettee.c
  31   '';
  32
  33   buildPhase = ''
  34     cat README.TXT
  35     mkdir -p $bin/bin
  36     $CC -o $bin/bin/nettee \
  37       -Wall -pedantic -std=c99\
  38       -D_LARGEFILE64_SOURCE -D_POSIX_SOURCE -D_XOPEN_SOURCE\
  39       nettee.c rb.c nio.c
  40   '';
  41
  42   installPhase = ''
  43     ${cleanPackaging.commonFileActions {
  44         docFiles = [
  45           "*.html"
  46           "*.TXT"
  47           "LICENSE"
  48           "*.sh"
  49           "topology.txt"
  50           "beowulf.master"
  51           "topology_info"
  52         ];
  53         noiseFiles = [
  54           "*.c"
  55           "*.h"
  56           "nettee"
  57         ];
  58       }} $doc/share/doc/nettee
  59
  60     mkdir -p $man/share/man/{man1,man3}
  61     mv nettee.1 $man/share/man/man1
  62     mv nettee_cmd.3 $man/share/man/man3
  63   '';
  64
  65   postFixup = ''
  66     ${cleanPackaging.checkForRemainingFiles}
  67   '';
  68
  69 }