pkgs/by-name/gd/gdm-settings/package.nix

   1 {
   2   lib,
   3   fetchFromGitHub,
   4   python3Packages,
   5   appstream,
   6   blueprint-compiler,
   7   desktop-file-utils,
   8   glib,
   9   gdm,
  10   libadwaita,
  11   meson,
  12   ninja,
  13   pkg-config,
  14   wrapGAppsHook4,
  15   # gdm-settings needs to know where to look for themes
  16   # This should work for most systems, but can be overridden if not
  17   dataDirs ? lib.concatStringsSep ":" [
  18     "/run/current-system/sw/share"
  19     "/usr/local/share"
  20     "/usr/share"
  21   ],
  22 }:
  23
  24 python3Packages.buildPythonApplication rec {
  25   pname = "gdm-settings";
  26   version = "4.4";
  27   pyproject = false;
  28
  29   src = fetchFromGitHub {
  30     owner = "gdm-settings";
  31     repo = "gdm-settings";
  32     rev = "refs/tags/v${version}";
  33     hash = "sha256-3Te8bhv2TkpJFz4llm1itRhzg9v64M7Drtrm4s9EyiQ=";
  34   };
  35
  36   nativeBuildInputs = [
  37     appstream # for appstream file validation
  38     blueprint-compiler
  39     desktop-file-utils # for desktop file validation
  40     glib # for `glib-compile-schemas`
  41     meson
  42     ninja
  43     pkg-config
  44     wrapGAppsHook4
  45   ];
  46
  47   buildInputs = [ libadwaita ];
  48
  49   dependencies = [ python3Packages.pygobject3 ];
  50
  51   dontWrapGApps = true;
  52   makeWrapperArgs = [
  53     "\${gappsWrapperArgs[@]}"
  54     "--set-default HOST_DATA_DIRS ${dataDirs}"
  55   ];
  56
  57   pythonImportsCheck = [ "gdms" ];
  58
  59   meta = {
  60     description = "Settings app for GNOME's Login Manager";
  61     homepage = "https://gdm-settings.github.io/";
  62     changelog = "https://github.com/gdm-settings/gdm-settings/releases/tag/v${version}";
  63     license = lib.licenses.agpl3Only;
  64     maintainers = with lib.maintainers; [ getchoo ];
  65     mainProgram = "gdm-settings";
  66     inherit (gdm.meta) platforms;
  67   };
  68 }