pkgs/by-name/go/godns/package.nix

   1 { lib
   2 , buildGoModule
   3 , fetchFromGitHub
   4 , nodejs
   5 , npmHooks
   6 , fetchNpmDeps
   7 , nix-update-script
   8 }:
   9
  10 buildGoModule rec {
  11   pname = "godns";
  12   version = "3.1.9";
  13
  14   src = fetchFromGitHub {
  15     owner = "TimothyYe";
  16     repo = "godns";
  17     rev = "refs/tags/v${version}";
  18     hash = "sha256-e39T6pOFD9FrbXVtD/qPN74HQqJcTl3a3enTPVqpsuY=";
  19   };
  20
  21   vendorHash = "sha256-zz33xHIZ2jhD2s3v2vum0ELG7GTqe5SsADUrO5yqumw=";
  22   npmDeps = fetchNpmDeps {
  23     src = "${src}/web";
  24     hash = "sha256-Y35CcUubO3QmbEwWBFXoWKLgvE8dp/mFE/szRigJvLo=";
  25   };
  26
  27   npmRoot = "web";
  28   nativeBuildInputs = [
  29     nodejs
  30     npmHooks.npmConfigHook
  31   ];
  32
  33   overrideModAttrs = oldAttrs: {
  34     # Do not add `npmConfigHook` to `goModules`
  35     nativeBuildInputs = lib.remove npmHooks.npmConfigHook oldAttrs.nativeBuildInputs;
  36     # Do not run `preBuild` when building `goModules`
  37     preBuild = null;
  38   };
  39
  40   # Some tests require internet access, broken in sandbox
  41   doCheck = false;
  42
  43   preBuild = ''
  44     npm --prefix="$npmRoot" run build
  45     go generate ./...
  46   '';
  47
  48   ldflags = [
  49     "-s"
  50     "-w"
  51     "-X main.Version=${version}"
  52   ];
  53
  54   passthru.updateScript = nix-update-script { };
  55
  56   meta = with lib; {
  57     description = "Dynamic DNS client tool supports AliDNS, Cloudflare, Google Domains, DNSPod, HE.net & DuckDNS & DreamHost, etc";
  58     homepage = "https://github.com/TimothyYe/godns";
  59     changelog = "https://github.com/TimothyYe/godns/releases/tag/v${version}";
  60     license = licenses.asl20;
  61     maintainers = with maintainers; [ yinfeng ];
  62     mainProgram = "godns";
  63   };
  64 }