pkgs/by-name/na/nawk/package.nix

   1 {
   2   lib,
   3   stdenv,
   4   fetchFromGitHub,
   5   bison,
   6   buildPackages,
   7   installShellFiles,
   8 }:
   9
  10 stdenv.mkDerivation (finalAttrs: {
  11   pname = "nawk";
  12   version = "20240728";
  13
  14   src = fetchFromGitHub {
  15     owner = "onetrueawk";
  16     repo = "awk";
  17     rev = finalAttrs.version;
  18     hash = "sha256-LA7fdbMP3aKJ1QljoKWizqVg3ys3hd8tGaRsQnIO+Hc=";
  19   };
  20
  21   depsBuildBuild = [ buildPackages.stdenv.cc ];
  22
  23   nativeBuildInputs = [ bison installShellFiles ];
  24
  25   outputs = [
  26     "out"
  27     "man"
  28   ];
  29
  30   makeFlags = [
  31     "CC=${stdenv.cc.targetPrefix}cc"
  32     "HOSTCC=${if stdenv.buildPlatform.isDarwin then "clang" else "cc"}"
  33   ];
  34
  35   installPhase = ''
  36     runHook preInstall
  37     mv a.out nawk
  38     installBin nawk
  39     mv awk.1 nawk.1
  40     installManPage nawk.1
  41     runHook postInstall
  42   '';
  43
  44   meta = {
  45     homepage = "https://awk.dev";
  46     description = "One, true implementation of AWK";
  47     longDescription = ''
  48       This is the version of awk described in "The AWK Programming Language",
  49       Second Edition, by Al Aho, Brian Kernighan, and Peter Weinberger
  50       (Addison-Wesley, 2023, ISBN 0-13-826972-6).
  51     '';
  52     changelog = "https://github.com/onetrueawk/awk/blob/${finalAttrs.src.rev}/ChangeLog";
  53     license = lib.licenses.mit;
  54     mainProgram = "nawk";
  55     maintainers = with lib.maintainers; [
  56       AndersonTorres
  57       konimex
  58     ];
  59     platforms = lib.platforms.all;
  60   };
  61 })