pkgs/tools/networking/telepresence/default.nix

   1 { lib, pythonPackages, fetchFromGitHub, makeWrapper
   2 , sshfs-fuse, torsocks, sshuttle, conntrack-tools , openssh, coreutils
   3 , iptables, bash }:
   4
   5 let
   6   sshuttle-telepresence = lib.overrideDerivation sshuttle (p: {
   7     postInstall = "mv $out/bin/sshuttle $out/bin/sshuttle-telepresence";
   8   });
   9 in pythonPackages.buildPythonPackage rec {
  10   pname = "telepresence";
  11   version = "0.109";
  12
  13   src = fetchFromGitHub {
  14     owner = "telepresenceio";
  15     repo = "telepresence";
  16     rev = version;
  17     sha256 = "1ccc8bzcdxp6rh6llk7grcnmyc05fq7dz5w0mifdzjv3a473hsky";
  18   };
  19
  20   nativeBuildInputs = [ makeWrapper ];
  21
  22   postInstall = ''
  23     wrapProgram $out/bin/telepresence \
  24       --prefix PATH : ${lib.makeBinPath [
  25         sshfs-fuse
  26         torsocks
  27         conntrack-tools
  28         sshuttle-telepresence
  29         openssh
  30         coreutils
  31         iptables
  32         bash
  33       ]}
  34   '';
  35
  36   doCheck = false;
  37
  38   meta = {
  39     homepage = "https://www.telepresence.io/";
  40     description = "Local development against a remote Kubernetes or OpenShift cluster";
  41     mainProgram = "telepresence";
  42     license = with lib.licenses; [ asl20 ];
  43     maintainers = with lib.maintainers; [ offline ];
  44   };
  45 }