pkgs/tools/text/xml/jing-trang/default.nix

   1 { lib, stdenv, fetchFromGitHub, jre_headless, jdk_headless, ant, saxon }:
   2
   3 stdenv.mkDerivation rec {
   4   pname = "jing-trang";
   5   version = "20181222";
   6
   7   src = fetchFromGitHub {
   8     owner = "relaxng";
   9     repo = "jing-trang";
  10     rev = "V${version}";
  11     hash = "sha256-Krupa3MGk5UaaQsaNpPMZuIUzHJytDiksz9ysCPkFS4=";
  12     fetchSubmodules = true;
  13   };
  14
  15   buildInputs = [ jdk_headless ant saxon ];
  16
  17   CLASSPATH = "lib/saxon.jar";
  18
  19   patches = [
  20     ./no-git-during-build.patch
  21   ];
  22
  23   preBuild = "ant";
  24
  25   installPhase = ''
  26     mkdir -p "$out"/{share/java,bin}
  27     cp ./build/*.jar ./lib/resolver.jar "$out/share/java/"
  28
  29     for tool in jing trang; do
  30     cat > "$out/bin/$tool" <<EOF
  31     #! $SHELL
  32     export JAVA_HOME='${jre_headless}'
  33     exec '${jre_headless}/bin/java' -jar '$out/share/java/$tool.jar' "\$@"
  34     EOF
  35     done
  36
  37     chmod +x "$out"/bin/*
  38   '';
  39
  40   doCheck = true;
  41   checkPhase = "ant test";
  42
  43   meta = with lib; {
  44     description = "RELAX NG validator in Java";
  45     # The homepage is www.thaiopensource.com, but it links to googlecode.com
  46     # for downloads and call it the "project site".
  47     homepage = "https://www.thaiopensource.com/relaxng/trang.html";
  48     platforms = platforms.unix;
  49     sourceProvenance = with sourceTypes; [
  50       fromSource
  51       binaryBytecode  # source bundles dependencies as jars
  52     ];
  53     maintainers = [ maintainers.bjornfor ];
  54   };
  55 }